#!/usr/bin/perl
# Draw graphs of HTTP transaction delays from http-stats output
# (c) 2003 Martin Mares <mj@ucw.cz>, GPL'ed

use strict;
use warnings;
use POSIX;

my $maxs = (@ARGV >= 1 && $ARGV[0] eq "--max");

my $datafile = "gp.tmp";
open D, ">$datafile" or die;

my @colnames = ();
my @ewma = ( 0, 0, 0, 0, 0, 0 );
my $ew = 0;
my $eww = 1-$ew;
while (<STDIN>) {
	chomp;
	if (/^#/) {
		s/^#\s+//;
		@colnames = split /\t/;
	} else {
		my $i = 0;
		s/\([^)]*\)//g;
		my %row = map { $colnames[$i++] => $_ } split /\t/;
		my $time = POSIX::strftime("%d-%m-%Y %H:%M:%S", localtime $row{'time'});
		my $n = $row{'NTimings'};
		my @r;
		if ($n) {
			@r = (
				$row{'TimeTotal'} / $n,
				$row{'TimeTMin'},
				$row{'TimeTMax'},
				$row{'TimeWait'} / $n,
				$row{'TimeWMin'},
				$row{'TimeWMax'}
			);
		} else {
			@r = ( 0, 0, 0, 0, 0, 0 );
		}
		print D "$time";
		for (my $i=0; $i<=$#r; $i++) {
			$ewma[$i] = $ew*$ewma[$i] + $eww*$r[$i];
			print D "\t", $ewma[$i];
		}
		print D "\n";
	}
}
close D;

my $ct = $maxs ? "Maximum" : "Average";
my $c1 = $maxs ? 5 : 3;
my $c2 = $maxs ? 8 : 6;

open GP, "|gnuplot" or die;
print GP <<EOF
set terminal png
set grid
set style data lines
set title "HTTP Transactions: $ct Timings"
set xlabel "Time"
set ylabel "seconds [EWMA $ew]"
set xdata time
set timefmt "%d-%m-%Y %H:%M:%S"
set format x "%d/%m\\n%H:%M"
#set xtics 86400
#set mxtics 3600
plot [] [0:30] \\
	"$datafile" using 1:$c1 title "Total time", \\
	"$datafile" using 1:$c2 title "Reply delay"
EOF
;
close GP;