dnl ###
dnl ### NSC -- Makefile Builder
dnl ### (c) 1997--2019 Martin Mares <mj@ucw.cz>
dnl ###
include(m4/dnslib.m4)

# Definition of primary domains; secondaries we needn't take care of

define(`PRIMARIES', `')

define(`nsc_prepend_cf_one', ` 'CFDIR/`nsc_file_name($1)')
define(`nsc_prepend_cf_multi', `nsc_iterate(`nsc_prepend_cf_one', $@)')
define(`nsc_key_dep', `ifelse(USE_DNSSEC,,,` 'khash/nsc_file_name($1) keys/resign-stamp)')
define(`PRIMARY', `define(`CURRENT_TARGET',zone/nsc_file_name($1))
divert(0)CURRENT_TARGET:nsc_prepend_cf_multi($@)nsc_key_dep($1) $(DDEPS)
	@bin/genzone nsc_file_name($1)`'nsc_prepend_cf_multi($@)

divert(-1)
define(`PRIMARIES', PRIMARIES zone/nsc_file_name($1))
')

define(`REVERSE', `PRIMARY(nsc_if_v6($1,`nsc_revblock6($1)',`nsc_revaddr($1)'), shift($@))')

define(`BLACKHOLE', `define(`NEED_BLACKHOLE', 1)')

define(`DSFOR', `divert(0)CURRENT_TARGET: dss/$1

divert(-1)')

# Insertion of raw makefile material

define(`MAKEFILE', `divert(0)$1
divert(-1)')

# Last words

define(`nsc_cleanup', `
ifdef(`NEED_BLACKHOLE', `PRIMARY(blackhole)')

divert(0)dnl
ver/.version: CFDIR/domains`'PRIMARIES`'ifdef(`NEED_BLACKHOLE',` zone/blackhole')
	NAMED_RESTART_CMD
	touch ver/.version

keys/resign-stamp:
	touch `$'@

clean:
	find bak zone hash tmp -maxdepth 1 -type f | xargs rm -f

clobber: clean
	rm -f Makefile named.conf bin/shell-env

distclean: clobber
	find ver -maxdepth 1 -type f | xargs rm -f
')

divert(0)dnl
`#'
`#'	Nameserver Configuration Makefile
`#'	Generated by NSCVER (mkmf.m4) on CURRENT_DATE
`#'	Please don't edit manually
`#'

DDEPS=m4/nsc.m4 m4/dnslib.m4 cf/config

all: ver/.version
m4wrap(`nsc_cleanup')
divert(-1)