# Simple Photo Gallery: Web Interface
# (c) 2003--2012 Martin Mares <mj@ucw.cz>

package UCW::Gallery::Web;

use strict;
use warnings;

use UCW::Gallery;
use UCW::CGI;
use File::Spec;

my $show_img;
my $want_archive;

my %args = (
	'i'	=> { 'var' => \$show_img, 'check' => '\d+' },
	'a'	=> { 'var' => \$want_archive },
);

sub error($) {
	print "<p style='color:red'>Bad luck, the script is broken. Sorry.\n<p>$_[0]\n";
	print "</body></html>\n";
}

sub get($$) {
	my ($self, $key) = @_;
	return $self->{gal}->get($key);
}

sub extras($$) {
	my ($self, $key) = @_;
	my $val = $self->get($key);
	if (ref $val eq 'CODE') {
		return &$val($self);
	} else {
		return $val;
	}
}

# For use by extras hooks
sub gallery($) {
	my ($self) = @_;
	return $self->{gal};
}

# For use by extras hooks: return true if we are showing an image page, false for index page
sub showing_image($) {
	my ($self) = @_;
	return $show_img ne "";
}

sub html_top($) {
	my ($self) = @_;
	my $title = UCW::CGI::html_escape($self->get('Title'));
	my $hextras = $self->extras('WebHeadExtras');
	my $theme_hextras = $self->theme_head_extras;
	print <<EOF ;
Content-Type: text/html

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN" "http://www.w3.org/TR/html4/strict.dtd">
<html><head>
$hextras$theme_hextras<title>$title</title>
</head><body>
EOF

	$UCW::CGI::ErrorHandler::error_hook = \&error;

	# WebTopExtras are evaluated separately, since they can override the error hook
	print $self->extras('WebTopExtras');
}

sub html_bot($) {
	my ($self) = @_;
	print $self->extras('WebBotExtras'), "</body></html>\n";
}

sub show_img($) {
	my ($self) = @_;

	if ($show_img < 1 || $show_img > $self->{num_photos}) {
		UCW::CGI::http_error('404 No such photo');
		return;
	}

	my $meta = $self->{meta};
	my $id = $meta->{sequence}->[$show_img-1];
	my $m = $meta->{photo}->{$id} or die;
	$self->html_top;

	$self->show_links(($show_img > 1 ? ("?i=".($show_img-1)) : ""),
			  ".",
			  ($show_img < $self->{num_photos} ? ("?i=".($show_img+1)) : ""));

	my $t = UCW::CGI::html_escape($m->{title});
	my $w = $m->{w};
	my $h = $m->{h};
	print "<h1>$t</h1>\n" if $t ne "";
	my $img = $self->get('PhotoUrlPrefix') . $self->{gal}->photo_file_name($m, $id);
	print "<p class=large><img src='$img' width=$w height=$h alt='$t'>\n";

	$self->html_bot;
}

sub show_pre_thumbs($) {
	my ($self) = @_;
}

sub show_post_thumbs($) {
	my ($self) = @_;
}

sub show_list($) {
	my ($self) = @_;
	$self->html_top;

	$self->show_links($self->get('BackURL'), $self->get('ParentURL'), $self->get('FwdURL'));
	print "<h1>", $self->get('Title'), "</h1>\n";
	my $subtitle = $self->get('SubTitle');
	print "<h2>$subtitle</h2>\n" if $subtitle ne "";
	$self->show_pre_thumbs;

	my $meta = $self->{meta};
	for my $idx (1..$self->{num_photos}) {
		my $id = $meta->{sequence}->[$idx-1];
		my $m = $meta->{photo}->{$id};
		my $click_url;
		if ($self->get('WebImageSubpages')) {
			$click_url = "?i=$idx";
		} else {
			$click_url = $self->get('PhotoUrlPrefix') . $self->{gal}->photo_file_name($m, $id);
		}
		$self->show_thumb($meta, $id, $click_url);
	}

	$self->show_post_thumbs;
	$self->html_bot();
}

sub dispatch($) {
	my ($self) = @_;
	binmode STDOUT, ':utf8';
	UCW::CGI::parse_args(\%args);
	$self->{meta} = $self->{gal}->read_meta(File::Spec->catfile($self->get('CacheDir'), 'cache.meta'));
	$self->{num_photos} = scalar @{$self->{meta}->{sequence}};

	if ($want_archive) {
		require UCW::Gallery::Archive;
		UCW::Gallery::Archive::send_archive($self->{gal}, $self->{meta});
	} elsif ($show_img ne "") {
		$self->show_img;
	} else {
		$self->show_list;
	}
}

sub attach($$) {
	my ($class, $gal) = @_;
	my $self = { gal => $gal };
	$gal->def(
		WebFE => $self,

		# Extras are either strings or functions called with the current gallery object as parameter
		WebHeadExtras => "",
		WebTopExtras => "",
		WebBotExtras => "",

		# Used by the theming logic
		WebThemeCSS => undef,

		# 1 if thumbnail link to sub-pages with images, 0 if they link directly to image files
		WebImageSubpages => 1,

		# If enabled, calling the CGI with a=zip produces a ZIP archive with all photos.
		WebAllowArchives => 1,
	);
	bless $self, $class;
	return $self;
}

42;
