update2

   1 #!/usr/bin/perl
   2 # This is a generic update/post-receive hook script for GIT repositories.
   3 # Written by Martin Mares <mj@ucw.cz> and placed into public domain.
   4
   5 use strict;
   6 use warnings;
   7
   8 use Getopt::Long;
   9 use IO::File;
  10 use File::Temp;
  11 use POSIX;
  12
  13 my $mail_to;
  14 my $subject_prefix = "GIT";
  15 my $max_diff_size;
  16
  17 GetOptions(
  18         'mail-to=s' => \$mail_to,
  19         'subject-prefix=s' => \$subject_prefix,
  20         'max-diff-size=s' => \$max_diff_size,
  21 ) and (@ARGV == 3 || !@ARGV) or die <<AMEN ;
  22 Usage as update hook: $0 [<options>] <refname> <sha1-old> <sha1-new>
  23 Usage as post-receive hook: $0 [<options>]
  24
  25 Options:
  26 --mail-to=<address>     Send mail to the given address
  27 --max-diff-size=<bytes> If the diff is too long, send just a summary
  28 --subject-prefix=<px>   Prefix subjects with [<px>] (default: GIT)
  29 AMEN
  30
  31 my $repo = POSIX::getcwd();
  32 $repo =~ s{.*/}{};
  33
  34 my @rev_list_options = ('--pretty', '--no-abbrev', '--date=iso');
  35 my @diff_options = ('-C');
  36
  37 sub update_ref($$$);
  38
  39 open ORIG_STDIN, '<&', \*STDIN;
  40 open ORIG_STDOUT, '>&', \*STDOUT;
  41
  42 if (@ARGV) {
  43         update_ref($ARGV[0], $ARGV[1], $ARGV[2]);
  44 } else {
  45         while (<ORIG_STDIN>) {
  46                 chomp;
  47                 my ($old, $new, $ref) = /^(\S+) (\S+) (.*)/ or die "Error parsing hook input ($_)\n";
  48                 update_ref($ref, $old, $new);
  49         }
  50 }
  51
  52 sub scan_branches($$) {
  53         my ($ref, $new) = @_;
  54         # Is there any branch pointing to $new (other than $ref)?
  55         for (`git branch -v --no-abbrev`) {
  56                 chomp;
  57                 my ($name, $sha) = /^..(\S+)\s+(\S+)/ or die;
  58                 if ((!defined($ref) || $name ne $ref) && $sha eq $new) {
  59                         return $name;
  60                 }
  61         }
  62         return;
  63 }
  64
  65 sub scan_commits($$) {
  66         my ($old, $new) = @_;
  67         my @commits = ();
  68         for (`git rev-list $old..$new --pretty=format:"# %H (%P) %s"`) {
  69                 chomp;
  70                 /^# / or next;
  71                 my ($hash, $parents, $subject) = m{^# (\S+) \(([^)]*)\) (.*)} or die;
  72                 push @commits, {
  73                         hash => $hash,
  74                         parents => [ split /\s+/, $parents ],
  75                         subject => $subject,
  76                 };
  77         }
  78         return @commits;
  79 }
  80
  81 sub most_recent($) {
  82         my ($new) = @_;
  83         print STDOUT "Most recent commits:\n\n";
  84         system 'git', 'rev-list', @rev_list_options, '--max-count=20', $new;
  85 }
  86
  87 sub output_size($) {
  88         my ($out) = @_;
  89         $out->seek(0, 2);
  90         return $out->tell;
  91 }
  92
  93 sub update_branch($$$$$)
  94 {
  95         my ($branch, $old, $new, $out, $headers) = @_;
  96
  97         my $subj = '[' . $subject_prefix . ($branch eq 'master' ? '' : "/$branch") . ']';
  98         if ($old =~ /^0+$/) {
  99                 # Creation of a branch
 100                 $subj .= ' Created branch';
 101                 my $copy_of = scan_branches($branch, $new);
 102                 if (defined $copy_of) {
 103                         $subj .= " as a copy of $copy_of";
 104                         print $out "Created branch $branch as a copy of $copy_of ($new).\n";
 105                 } else {
 106                         print $out "Created branch $branch ($new).\n\n";
 107                         most_recent($new);
 108                 }
 109         } elsif ($new =~ /^0+$/) {
 110                 # Deletion of a branch
 111                 $subj .= ' Branch deleted';
 112                 print $out "Deleted branch $branch ($old).\n";
 113         } else {
 114                 my $lca = `git merge-base $old $new`; die if $?;
 115                 chomp $lca;
 116                 if ($lca eq $old) {
 117                         # Fast forward ... scan all objects
 118                         my @commits = scan_commits($old, $new);
 119                         my @nonmerges = grep { @{$_->{parents}} == 1 } @commits;
 120                         @commits or return;
 121
 122                         # Construct subject
 123                         # Try to recognize simple merges and display them as such
 124                         my $c0 = $commits[0];
 125                         my $n0 = $nonmerges[0];
 126                         my $c0p = $c0->{parents};
 127                         if (@{$c0p} == 2 &&
 128                             ($c0p->[0] eq $old || $c0p->[1] eq $old) &&
 129                             $c0->{subject} =~ m{^\s*Merge branch '([^']*)' into (\S+)} &&
 130                             (($1 eq $branch) != ($2 eq $branch))) {
 131                                 # Pushed a merge of the current branch with another local branch
 132                                 $subj .= ' ' . $c0->{subject};
 133                         } elsif ($n0) {
 134                                 # Otherwise take the subject of the first non-merge commit
 135                                 $subj .= ' ' . $n0->{subject};
 136                         } else {
 137                                 # If there is none, take the first merge
 138                                 $subj .= ' ' . $c0->{subject};
 139                         }
 140
 141                         print $out "Push to branch $branch ($old -> $new)\n\n";
 142
 143                         # If there are multiple commits, mention that
 144                         if (@nonmerges > 1) {
 145                                 $subj .= ' [' . (scalar @commits) . ' commits]';
 146                                 print $out 'Pushed ', (scalar @commits), " commits. Overall diffstat:\n\n";
 147                         }
 148
 149                         # Print an overall diffstat
 150                         system 'git', 'diff', '--stat', $old, $new;
 151                         print $out "\n";
 152                         my $pos_after_header = output_size($out);
 153
 154                         # Show individual commits with diffs
 155                         system 'git', 'log', @rev_list_options, @diff_options, '-p', "$old..$new";
 156
 157                         # If the file is too long, truncate it and print just a summary
 158                         if (defined($max_diff_size) && output_size($out) > $max_diff_size) {
 159                                 $out->truncate($pos_after_header);
 160                                 output_size($out);
 161                                 print $out "Diff was too long, printing just a summary.\n\n";
 162                                 system 'git', 'log', @rev_list_options, "$old..$new";
 163                         }
 164                 } elsif ($lca eq $new) {
 165                         # Rewind
 166                         $subj .= ' Branch rewound';
 167                         print $out "Rewound branch $branch ($old -> $new).\n\n";
 168                         most_recent($new);
 169                 } else {
 170                         # Otherwise it is a rebase
 171                         $subj .= ' Branch rebased';
 172                         print $out "Rebased branch $branch ($old -> $new).\n\n";
 173                         print $out "Commits from common ancestor:\n\n";
 174                         system 'git', 'rev-list', @rev_list_options, $new, "^$old";
 175                 }
 176         }
 177
 178         $headers->{'Subject'} = $subj;
 179         $headers->{'X-Git-Branch'} = $branch;
 180         return 1;
 181 }
 182
 183 sub update_tag($$$$$)
 184 {
 185         my ($tag, $old, $new, $out, $headers) = @_;
 186
 187         my $subj = '[' . $subject_prefix . ']';
 188         if ($new =~ /^0+$/) {
 189                 $subj .= " Deleted tag $tag";
 190                 print $out "Deleted tag $tag ($old).\n";
 191         } else {
 192                 my $copy_of = scan_branches(undef, $new);
 193                 my $cp = defined($copy_of) ? " to branch $copy_of" : "";
 194                 if ($old =~ /^0+/) {
 195                         $subj .= " Created tag $tag$cp";
 196                         print $out "Created tag $tag$cp ($new).\n\n";
 197                 } else {
 198                         $subj .= " Changed tag $tag$cp";
 199                         print $out "Changed tag $tag$cp ($old -> $new).\n\n";
 200                 }
 201                 most_recent($new);
 202         }
 203
 204         $headers->{'Subject'} = $subj;
 205         $headers->{'X-Git-Tag'} = $tag;
 206         return 1;
 207 }
 208
 209 sub update_ref($$$)
 210 {
 211         my ($ref, $old, $new) = @_;
 212         $old ne $new or return;
 213         my ($type, $name) = ($ref =~ m{^refs/([^/]*)/(.*)}) or return;
 214
 215         my $out = File::Temp->new() or die;
 216         my $outname = $out->filename;
 217         $out->autoflush(1);
 218         close STDOUT;
 219         open STDOUT, '>&', $out or die;
 220
 221         my $headers = {
 222                 'X-Git-Repo' => $repo,
 223                 'X-Git-Old-SHA' => $old,
 224                 'X-Git-New-SHA' => $new,
 225         };
 226
 227         my $send;
 228         if ($type eq 'heads') { $send = update_branch($name, $old, $new, $out, $headers); }
 229         elsif ($type eq 'tags') { $send = update_tag($name, $old, $new, $out, $headers); }
 230         $out->close();
 231         $send or return;
 232
 233         if (defined $mail_to) {
 234                 close STDIN;
 235                 open STDIN, '<', $outname;
 236                 my @mutt = (
 237                         'mutt',
 238                         '-F/dev/null',
 239                         '-x',
 240                         '-e', 'set charset="utf-8"',
 241                         '-e', 'set send_charset="us-ascii:iso-8859-2:utf-8"',
 242                         '-s', $headers->{'Subject'},
 243                 );
 244                 delete $headers->{'Subject'};
 245                 push @mutt, map { ('-e', "my_hdr $_: " . $headers->{$_}) } keys %$headers;
 246                 system @mutt, $mail_to;
 247         } else {
 248                 open STDOUT, '>&', \*ORIG_STDOUT;
 249                 print map { "$_: " . $headers->{$_} . "\n" } sort keys %$headers;
 250                 print "\n";
 251                 system 'cat', $outname;
 252                 print "\n";
 253         }
 254 }