ucw/perl/UCW/Configure/C.pm

   1 # UCW Library configuration system: OS and C compiler
   2 # (c) 2005--2012 Martin Mares <mj@ucw.cz>
   3 # (c) 2006 Robert Spalek <robert@ucw.cz>
   4 # (c) 2008 Michal Vaner <vorner@ucw.cz>
   5
   6 ### OS ###
   7
   8 package UCW::Configure::C;
   9 use UCW::Configure;
  10
  11 use strict;
  12 use warnings;
  13
  14 Test("OS", "Checking on which OS we run", sub {
  15         my $os = `uname`;
  16         chomp $os;
  17         Fail "Unable to determine OS type" if $? || $os eq "";
  18         return $os;
  19 });
  20
  21 if (Get("OS") eq "Linux") {
  22         Set("CONFIG_LINUX");
  23 } elsif (Get("OS") eq "Darwin") {
  24         Set("CONFIG_DARWIN");
  25 } else {
  26         Fail "Don't know how to run on this operating system.";
  27 }
  28
  29 ### Compiler ###
  30
  31 # Default compiler
  32 Test("CC", "Checking for C compiler", sub { return "gcc"; });
  33
  34 # GCC version
  35 Test("GCCVER", "Checking for GCC version", sub {
  36         my $gcc = Get("CC");
  37         my $ver = `$gcc --version | sed '2,\$d; s/^\\(.* \\)*\\([0-9]*\\.[0-9]*\\).*/\\2/'`;
  38         chomp $ver;
  39         Fail "Unable to determine GCC version" if $? || $ver eq "";
  40         return $ver;
  41 });
  42 my ($gccmaj, $gccmin) = split(/\./, Get("GCCVER"));
  43 my $gccver = 1000*$gccmaj + $gccmin;
  44 $gccver >= 3000 or Fail "GCC older than 3.0 doesn't support C99 well enough.";
  45
  46 ### CPU ###
  47
  48 Test("ARCH", "Checking for machine architecture", sub {
  49         #
  50         # We have to ask GCC for the target architecture, because it may
  51         # differ from what uname tells us. This can happen even if we are
  52         # not cross-compiling, for example on Linux with amd64 kernel, but
  53         # i386 userspace.
  54         #
  55         my $gcc = Get("CC");
  56         my $mach = `$gcc -dumpmachine 2>/dev/null`;
  57         if (!$? && $mach ne "") {
  58                 $mach =~ s/-.*//;
  59         } else {
  60                 $mach = `uname -m`;
  61                 Fail "Unable to determine machine type" if $? || $mach eq "";
  62         }
  63         chomp $mach;
  64         if ($mach =~ /^i[0-9]86$/) {
  65                 return "i386";
  66         } elsif ($mach =~ /^(x86[_-]|amd)64$/) {
  67                 return "amd64";
  68         } else {
  69                 return "unknown ($mach)";
  70         }
  71 });
  72
  73 my $arch = Get("ARCH");
  74 if ($arch eq 'i386') {
  75         Set("CPU_I386");
  76         UnSet("CPU_64BIT_POINTERS");
  77         Set("CPU_LITTLE_ENDIAN");
  78         UnSet("CPU_BIG_ENDIAN");
  79         Set("CPU_ALLOW_UNALIGNED");
  80         Set("CPU_STRUCT_ALIGN" => 4);
  81 } elsif ($arch eq "amd64") {
  82         Set("CPU_AMD64");
  83         Set("CPU_64BIT_POINTERS");
  84         Set("CPU_LITTLE_ENDIAN");
  85         UnSet("CPU_BIG_ENDIAN");
  86         Set("CPU_ALLOW_UNALIGNED");
  87         Set("CPU_STRUCT_ALIGN" => 8);
  88 } elsif (!Get("CPU_LITTLE_ENDIAN") && !Get("CPU_BIG_ENDIAN")) {
  89         Fail "Architecture not recognized, please set CPU_xxx variables manually.";
  90 }
  91
  92 ### Compiler and its Options ###
  93
  94 # C flags: tell the compiler we're speaking C99, and disable common symbols
  95 Set("CLANG" => "-std=gnu99 -fno-common");
  96
  97 # C optimizations
  98 Set("COPT" => '-O2');
  99 if ($arch =~ /^(i386|amd64)$/ && Get("CONFIG_EXACT_CPU")) {
 100         if ($gccver >= 4002) {
 101                 Append('COPT', '-march=native');
 102         } else {
 103                 Warn "CONFIG_EXACT_CPU not supported with old GCC, ignoring.\n";
 104         }
 105 }
 106
 107 # C optimizations for highly exposed code
 108 Set("COPT2" => '-O3');
 109
 110 # Warnings
 111 Set("CWARNS" => '-Wall -W -Wno-parentheses -Wstrict-prototypes -Wmissing-prototypes');
 112 Set("CWARNS_OFF" => '');
 113
 114 # Linker flags
 115 Set("LOPT" => "");
 116
 117 # Extra libraries
 118 Set("LIBS" => "");
 119
 120 # Extra flags for compiling and linking shared libraries
 121 Set("CSHARED" => '-fPIC');
 122 Append("LOPT" => "-Wl,--rpath-link,run/lib -Lrun/lib");
 123 if (!IsSet("CONFIG_LOCAL")) {
 124         # Beware that in non-local builds the INSTALL_LIB_DIR must exist in
 125         # standard search paths for shared libraries.
 126         Set("SO_LINK_PATH" => '');
 127 }
 128 else {
 129         # In local builds, we need to link binaries with custom --rpath.
 130         # GCC seems to fail when this directory does not exist.
 131         Set("SO_LINK_PATH" => "-Wl,--rpath," . Get("INSTALL_LIB_DIR"));
 132         AtWrite {
 133                 my $libdir = Get("INSTALL_LIB_DIR");
 134                 if (IsSet("CONFIG_SHARED")) {
 135                         `mkdir -p $libdir`; Fail("Cannot create $libdir") if $?;
 136                 }
 137         };
 138 }
 139 if (IsSet("CONFIG_DARWIN")) {
 140         Set("LSHARED" => '-dynamiclib -install_name $(@F)$(SONAME_SUFFIX) -undefined dynamic_lookup');
 141 } else {
 142         Set("LSHARED" => '-shared -Wl,-soname,$(@F)$(SONAME_SUFFIX)');
 143 }
 144
 145 # Extra switches depending on GCC version:
 146 if ($gccver == 3000) {
 147         Append("COPT" => "-fstrict-aliasing");
 148 } elsif ($gccver == 3003) {
 149         Append("CWARNS" => "-Wundef -Wredundant-decls");
 150         Append("COPT" => "-finline-limit=20000 --param max-inline-insns-auto=1000");
 151 } elsif ($gccver == 3004) {
 152         Append("CWARNS" => "-Wundef -Wredundant-decls");
 153         Append("COPT" => "-finline-limit=2000 --param large-function-insns=5000 --param inline-unit-growth=200 --param large-function-growth=400");
 154 } elsif ($gccver >= 4000) {
 155         Append("CWARNS" => "-Wundef -Wredundant-decls -Wno-pointer-sign -Wdisabled-optimization -Wno-missing-field-initializers");
 156         Append("CWARNS_OFF" => "-Wno-pointer-sign");
 157         Append("COPT" => "-finline-limit=5000 --param large-function-insns=5000 --param inline-unit-growth=200 --param large-function-growth=400");
 158 } else {
 159         Warn "Don't know anything about this GCC version, using default switches.\n";
 160 }
 161
 162 if (IsSet("CONFIG_DEBUG")) {
 163         # If debugging:
 164         Set("DEBUG_ASSERTS");
 165         Set("DEBUG_DIE_BY_ABORT") if Get("CONFIG_DEBUG") > 1;
 166         Set("CDEBUG" => "-ggdb");
 167 } else {
 168         # If building a release version:
 169         Append("COPT" => "-fomit-frame-pointer");
 170         Append("LOPT" => "-s");
 171 }
 172
 173 # Link-time optimization (experimental)
 174 # This is currently very inefficient, because we do not attempt to disable
 175 # optimizations when compiling individual modules. Therefore, we optimize
 176 # each shared library module twice: when compiling and when linking.
 177 # Doing it properly would require hacking makefiles.
 178 if (IsSet("CONFIG_LTO")) {
 179         Append("LOPT", "-flto");
 180         Append("COPT", "-flto");
 181 }
 182
 183 if (IsSet("CONFIG_DARWIN")) {
 184         # gcc-4.0 on Darwin doesn't set this in the gnu99 mode
 185         Append("CLANG" => "-fnested-functions");
 186         # Directory hierarchy of the fink project
 187         Append("LIBS" => "-L/sw/lib");
 188         Append("COPT" => "-I/sw/include");
 189 }
 190
 191 ### Compiling test programs ###
 192
 193 sub TestCompile($$) {
 194         my ($testname, $source) = @_;
 195         my $dir = "conftest-$testname";
 196         `rm -rf $dir && mkdir $dir`; $? and Fail "Cannot initialize $dir";
 197
 198         open SRC, ">$dir/conftest.c";
 199         print SRC $source;
 200         close SRC;
 201
 202         my $cmd = join(" ",
 203                 map { defined($_) ? $_ : "" }
 204                         "cd $dir &&",
 205                         Get("CC"), Get("CLANG"), Get("COPT"), Get("CEXTRA"), Get("LIBS"),
 206                         "conftest.c", "-o", "conftest",
 207                         ">conftest.log", "2>&1"
 208                 );
 209         `$cmd`;
 210         my $result = !$?;
 211
 212         `rm -rf $dir` unless Get("KEEP_CONFTEST");
 213
 214         return $result;
 215 }
 216
 217 ### Writing C headers with configuration ###
 218
 219 sub ConfigHeader($$) {
 220         my ($hdr, $rules) = @_;
 221         Log "Generating $hdr ... ";
 222         open X, ">obj/$hdr" or Fail $!;
 223         print X "/* Generated automatically by $0, please don't touch manually. */\n";
 224
 225         sub match_rules($$) {
 226                 my ($rules, $name) = @_;
 227                 for (my $i=0; $i < scalar @$rules; $i++) {
 228                         my ($r, $v) = ($rules->[$i], $rules->[$i+1]);
 229                         return $v if $name =~ $r;
 230                 }
 231                 return 0;
 232         }
 233
 234         foreach my $x (sort keys %UCW::Configure::vars) {
 235                 next unless match_rules($rules, $x);
 236                 my $v = $UCW::Configure::vars{$x};
 237                 # Try to add quotes if necessary
 238                 $v = '"' . $v . '"' unless ($v =~ /^"/ || $v =~ /^\d*$/);
 239                 print X "#define $x $v\n";
 240         }
 241         close X;
 242         Log "done\n";
 243 }
 244
 245 AtWrite {
 246         ConfigHeader("autoconf.h", [
 247                 # Symbols with "_" anywhere in their name are exported
 248                 "_" => 1
 249         ]);
 250 };
 251
 252 # Return success
 253 1;