ucw/perl/UCW/CGI.pm

   1 #       Poor Man's CGI Module for Perl
   2 #
   3 #       (c) 2002--2010 Martin Mares <mj@ucw.cz>
   4 #       Slightly modified by Tomas Valla <tom@ucw.cz>
   5 #
   6 #       This software may be freely distributed and used according to the terms
   7 #       of the GNU Lesser General Public License.
   8
   9 # FIXME:
  10 # - respond with proper HTTP error codes
  11 # - if we get invalid parameters, generate HTTP error or redirect
  12
  13 package UCW::CGI;
  14
  15 # First of all, set up error handling, so that even errors during parsing
  16 # will be reported properly.
  17
  18 # Variables to be set by the calling module:
  19 #       $UCW::CGI::error_mail           mail address of the script admin (optional)
  20 #                                       (this one has to be set in the BEGIN block!)
  21 #       $UCW::CGI::error_hook           function to be called for reporting errors
  22
  23 my $error_reported;
  24 my $exit_code;
  25 my $debug = 0;
  26
  27 sub report_bug($)
  28 {
  29         if (!defined $error_reported) {
  30                 $error_reported = 1;
  31                 print STDERR $_[0];
  32                 if (defined($UCW::CGI::error_hook)) {
  33                         &$UCW::CGI::error_hook($_[0]);
  34                 } else {
  35                         print "Content-type: text/plain\n\n";
  36                         print "Internal bug:\n";
  37                         print $_[0], "\n";
  38                         print "Please notify $UCW::CGI::error_mail\n" if defined $UCW::CGI::error_mail;
  39                 }
  40         }
  41         die;
  42 }
  43
  44 BEGIN {
  45         $SIG{__DIE__} = sub { report_bug($_[0]); };
  46         $SIG{__WARN__} = sub { report_bug("WARNING: " . $_[0]); };
  47         $exit_code = 0;
  48 }
  49
  50 END {
  51         $? = $exit_code;
  52 }
  53
  54 use strict;
  55 use warnings;
  56
  57 require Exporter;
  58 our $VERSION = 1.0;
  59 our @ISA = qw(Exporter);
  60 our @EXPORT = qw(&html_escape &url_escape &url_deescape &url_param_escape &url_param_deescape &self_ref &self_form &http_get);
  61 our @EXPORT_OK = qw();
  62
  63 ### Escaping ###
  64
  65 sub url_escape($) {
  66         my $x = shift @_;
  67         $x =~ s/([^-\$_.!*'(),0-9A-Za-z\x80-\xff])/"%".unpack('H2',$1)/ge;
  68         return $x;
  69 }
  70
  71 sub url_deescape($) {
  72         my $x = shift @_;
  73         $x =~ s/%(..)/pack("H2",$1)/ge;
  74         return $x;
  75 }
  76
  77 sub url_param_escape($) {
  78         my $x = shift @_;
  79         $x = url_escape($x);
  80         $x =~ s/%20/+/g;
  81         return $x;
  82 }
  83
  84 sub url_param_deescape($) {
  85         my $x = shift @_;
  86         $x =~ s/\+/ /g;
  87         return url_deescape($x);
  88 }
  89
  90 sub html_escape($) {
  91         my $x = shift @_;
  92         $x =~ s/&/&amp;/g;
  93         $x =~ s/</&lt;/g;
  94         $x =~ s/>/&gt;/g;
  95         $x =~ s/"/&quot;/g;
  96         $x =~ s/'/&#39;/g;
  97         return $x;
  98 }
  99
 100 ### Analysing RFC 822 Style Headers ###
 101
 102 sub rfc822_prepare($) {
 103         my $x = shift @_;
 104         # Convert all %'s and backslash escapes to %xx escapes
 105         $x =~ s/%/%25/g;
 106         $x =~ s/\\(.)/"%".unpack("H2",$1)/ge;
 107         # Remove all comments, beware, they can be nested (unterminated comments are closed at EOL automatically)
 108         while ($x =~ s/^(("[^"]*"|[^"(])*(\([^)]*)*)(\([^()]*(\)|$))/$1 /) { }
 109         # Remove quotes and escape dangerous characters inside (again closing at the end automatically)
 110         $x =~ s{"([^"]*)("|$)}{my $z=$1; $z =~ s/([^0-9a-zA-Z%_-])/"%".unpack("H2",$1)/ge; $z;}ge;
 111         # All control characters are properly escaped, tokens are clearly visible.
 112         # Finally remove all unnecessary spaces.
 113         $x =~ s/\s+/ /g;
 114         $x =~ s/(^ | $)//g;
 115         $x =~ s{\s*([()<>@,;:\\"/\[\]?=])\s*}{$1}g;
 116         return $x;
 117 }
 118
 119 sub rfc822_deescape($) {
 120         my $x = shift @_;
 121         return url_deescape($x);
 122 }
 123
 124 ### Reading of HTTP headers ###
 125
 126 sub http_get($) {
 127         my $h = shift @_;
 128         $h =~ tr/a-z-/A-Z_/;
 129         return $ENV{"HTTP_$h"} || $ENV{"$h"};
 130 }
 131
 132 ### Parsing of Arguments ###
 133
 134 my $main_arg_table;
 135 my %raw_args;
 136
 137 sub parse_raw_args($) {
 138         my ($s) = @_;
 139         $s =~ s/\s+//;
 140         for $_ (split /[&:]/, $s) {
 141                 (/^([^=]+)=(.*)$/) or next;
 142                 my $arg = $1;
 143                 $_ = $2;
 144                 s/\+/ /g;
 145                 s/%(..)/pack("H2",$1)/eg;
 146                 s/\r\n/\n/g;
 147                 s/\r/\n/g;
 148                 $raw_args{$arg} = $_;
 149         }
 150 }
 151
 152 sub parse_multipart_form_data();
 153
 154 sub init_args() {
 155         if (!defined $ENV{"GATEWAY_INTERFACE"}) {
 156                 print STDERR "Must be called as a CGI script.\n";
 157                 $exit_code = 1;
 158                 exit;
 159         }
 160
 161         my $method = $ENV{"REQUEST_METHOD"};
 162         if (my $qs = $ENV{"QUERY_STRING"}) {
 163                 parse_raw_args($qs);
 164         }
 165         if ($method eq "GET") {
 166         } elsif ($method eq "POST") {
 167                 if ($ENV{"CONTENT_TYPE"} =~ /^application\/x-www-form-urlencoded\b/i) {
 168                         while (<STDIN>) {
 169                                 chomp;
 170                                 parse_raw_args($_);
 171                         }
 172                 } elsif ($ENV{"CONTENT_TYPE"} =~ /^multipart\/form-data\b/i) {
 173                         parse_multipart_form_data();
 174                 } else {
 175                         die "Unknown content type for POST data";
 176                 }
 177         } else {
 178                 die "Unknown request method";
 179         }
 180 }
 181
 182 sub parse_args($) {                     # CAVEAT: attached files must be defined in the main arg table
 183         my $args = shift @_;
 184         if (!$main_arg_table) {
 185                 $main_arg_table = $args;
 186                 init_args();
 187         }
 188
 189         for my $a (values %$args) {
 190                 my $r = ref($a->{'var'});
 191                 defined($a->{'default'}) or $a->{'default'}="";
 192                 if ($r eq 'SCALAR') {
 193                         ${$a->{'var'}} = $a->{'default'};
 194                 } elsif ($r eq 'ARRAY') {
 195                         @{$a->{'var'}} = ();
 196                 }
 197         }
 198
 199         for my $a (values %$args) {
 200                 defined($raw_args{$a}) or next;
 201                 $_ = $raw_args{$a};
 202                 $a->{'multiline'} or s/(\n|\t)/ /g;
 203                 s/^\s+//;
 204                 s/\s+$//;
 205                 if (my $rx = $a->{'check'}) {
 206                         if (!/^$rx$/) { $_ = $a->{'default'}; }
 207                 }
 208
 209                 my $v = $a->{'var'};
 210                 my $r = ref($v);
 211                 if ($r eq 'SCALAR') {
 212                         $$v = $_;
 213                 } elsif ($r eq 'ARRAY') {
 214                         push @$v, $_;
 215                 }
 216         }
 217 }
 218
 219 ### Parsing Multipart Form Data ###
 220
 221 my $boundary;
 222 my $boundary_len;
 223 my $mp_buffer;
 224 my $mp_buffer_i;
 225 my $mp_buffer_boundary;
 226 my $mp_eof;
 227
 228 sub refill_mp_data($) {
 229         my ($more) = @_;
 230         if ($mp_buffer_boundary >= $mp_buffer_i) {
 231                 return $mp_buffer_boundary - $mp_buffer_i;
 232         } elsif ($mp_buffer_i + $more <= length($mp_buffer) - $boundary_len) {
 233                 return $more;
 234         } else {
 235                 if ($mp_buffer_i) {
 236                         $mp_buffer = substr($mp_buffer, $mp_buffer_i);
 237                         $mp_buffer_i = 0;
 238                 }
 239                 while ($mp_buffer_i + $more > length($mp_buffer) - $boundary_len) {
 240                         last if $mp_eof;
 241                         my $data;
 242                         my $n = read(STDIN, $data, 2048);
 243                         if ($n > 0) {
 244                                 $mp_buffer .= $data;
 245                         } else {
 246                                 $mp_eof = 1;
 247                         }
 248                 }
 249                 $mp_buffer_boundary = index($mp_buffer, $boundary, $mp_buffer_i);
 250                 if ($mp_buffer_boundary >= 0) {
 251                         return $mp_buffer_boundary;
 252                 } elsif ($mp_eof) {
 253                         return length($mp_buffer);
 254                 } else {
 255                         return length($mp_buffer) - $boundary_len;
 256                 }
 257         }
 258 }
 259
 260 sub get_mp_line($) {
 261         my ($allow_empty) = @_;
 262         my $n = refill_mp_data(1024);
 263         my $i = index($mp_buffer, "\r\n", $mp_buffer_i);
 264         if ($i >= $mp_buffer_i && $i < $mp_buffer_i + $n - 1) {
 265                 my $s = substr($mp_buffer, $mp_buffer_i, $i - $mp_buffer_i);
 266                 $mp_buffer_i = $i + 2;
 267                 return $s;
 268         } elsif ($allow_empty) {
 269                 if ($n) {                                                       # An incomplete line
 270                         my $s = substr($mp_buffer, $mp_buffer_i, $n);
 271                         $mp_buffer_i += $n;
 272                         return $s;
 273                 } else {                                                        # No more lines
 274                         return undef;
 275                 }
 276         } else {
 277                 die "Premature end of multipart POST data";
 278         }
 279 }
 280
 281 sub skip_mp_boundary() {
 282         if ($mp_buffer_boundary != $mp_buffer_i) {
 283                 die "Premature end of multipart POST data";
 284         }
 285         $mp_buffer_boundary = -1;
 286         $mp_buffer_i += 2;
 287         my $b = get_mp_line(0);
 288         print STDERR "SEP $b\n" if $debug;
 289         $mp_buffer_boundary = index($mp_buffer, $boundary, $mp_buffer_i);
 290         if (substr("\r\n$b", 0, $boundary_len) eq "$boundary--") {
 291                 return 0;
 292         } else {
 293                 return 1;
 294         }
 295 }
 296
 297 sub parse_mp_header() {
 298         my $h = {};
 299         my $last;
 300         while ((my $l = get_mp_line(0)) ne "") {
 301                 print STDERR "HH $l\n" if $debug;
 302                 if (my ($name, $value) = ($l =~ /([A-Za-z0-9-]+)\s*:\s*(.*)/)) {
 303                         $name =~ tr/A-Z/a-z/;
 304                         $h->{$name} = $value;
 305                         $last = $name;
 306                 } elsif ($l =~ /^\s+/ && $last) {
 307                         $h->{$last} .= $l;
 308                 } else {
 309                         $last = undef;
 310                 }
 311         }
 312         foreach my $n (keys %$h) {
 313                 $h->{$n} = rfc822_prepare($h->{$n});
 314                 print STDERR "H $n: $h->{$n}\n" if $debug;
 315         }
 316         return (keys %$h) ? $h : undef;
 317 }
 318
 319 sub parse_multipart_form_data() {
 320         # First of all, find the boundary string
 321         my $ct = rfc822_prepare($ENV{"CONTENT_TYPE"});
 322         if (!(($boundary) = ($ct =~ /^.*;boundary=([^; ]+)/))) {
 323                 die "Multipart content with no boundary string received";
 324         }
 325         $boundary = rfc822_deescape($boundary);
 326         print STDERR "BOUNDARY IS $boundary\n" if $debug;
 327
 328         # BUG: IE 3.01 on Macintosh forgets to add the "--" at the start of the boundary string
 329         # as the MIME specs preach. Workaround borrowed from CGI.pm in Perl distribution.
 330         my $agent = http_get("User-agent") || "";
 331         $boundary = "--$boundary" unless $agent =~ /MSIE\s+3\.0[12];\s*Mac/;
 332         $boundary = "\r\n$boundary";
 333         $boundary_len = length($boundary) + 2;
 334
 335         # Check upload size in advance
 336         if (my $size = http_get("Content-Length")) {
 337                 my $max_allowed = 0;
 338                 foreach my $a (values %$main_arg_table) {
 339                         $max_allowed += $a->{"maxsize"} || 65536;
 340                 }
 341                 if ($size > $max_allowed) {
 342                         die "Maximum form data length exceeded";
 343                 }
 344         }
 345
 346         # Initialize our buffering mechanism and part splitter
 347         $mp_buffer = "\r\n";
 348         $mp_buffer_i = 0;
 349         $mp_buffer_boundary = -1;
 350         $mp_eof = 0;
 351
 352         # Skip garbage before the 1st part
 353         while (my $i = refill_mp_data(256)) { $mp_buffer_i += $i; }
 354         skip_mp_boundary() || return;
 355
 356         # Process individual parts
 357         do { PART: {
 358                 print STDERR "NEXT PART\n" if $debug;
 359                 my $h = parse_mp_header();
 360                 my ($field, $cdisp, $a);
 361                 if ($h &&
 362                     ($cdisp = $h->{"content-disposition"}) &&
 363                     $cdisp =~ /^form-data/ &&
 364                     (($field) = ($cdisp =~ /;name=([^;]+)/)) &&
 365                     ($a = $main_arg_table->{"$field"})) {
 366                         print STDERR "FIELD $field\n" if $debug;
 367                         if (defined $h->{"content-transfer-encoding"}) { die "Unexpected Content-Transfer-Encoding"; }
 368                         if (defined $a->{"var"}) {
 369                                 while (defined (my $l = get_mp_line(1))) {
 370                                         print STDERR "VALUE $l\n" if $debug;
 371                                         parse_raw_args("$field=$l");
 372                                 }
 373                                 next PART;
 374                         } elsif (defined $a->{"file"}) {
 375                                 require File::Temp;
 376                                 require IO::Handle;
 377                                 my $max_size = $a->{"maxsize"} || 1048576;
 378                                 my @tmpargs = (undef, UNLINK => 1);
 379                                 push @tmpargs, DIR => $a->{"tmpdir"} if defined $a->{"tmpdir"};
 380                                 my ($fh, $fn) = File::Temp::tempfile(@tmpargs);
 381                                 print STDERR "FILE UPLOAD to $fn\n" if $debug;
 382                                 ${$a->{"file"}} = $fn;
 383                                 ${$a->{"fh"}} = $fh if defined $a->{"fh"};
 384                                 my $total_size = 0;
 385                                 while (my $i = refill_mp_data(4096)) {
 386                                         print $fh substr($mp_buffer, $mp_buffer_i, $i);
 387                                         $mp_buffer_i += $i;
 388                                         $total_size += $i;
 389                                         if ($total_size > $max_size) { die "Uploaded file too long"; }
 390                                 }
 391                                 $fh->flush();   # Don't close the handle, the file would disappear otherwise
 392                                 next PART;
 393                         }
 394                 }
 395                 print STDERR "SKIPPING\n" if $debug;
 396                 while (my $i = refill_mp_data(256)) { $mp_buffer_i += $i; }
 397         } } while (skip_mp_boundary());
 398 }
 399
 400 ### Generating Self-ref URL's ###
 401
 402 sub make_out_args(@) {          # Usage: make_out_args([arg_table, ...] name => value, ...)
 403         my @arg_tables = ( $main_arg_table );
 404         while (@_ && ref(@_) eq 'HASH') {
 405                 push @arg_tables, shift @_;
 406         }
 407         my %overrides = @_;
 408         my $out = {};
 409         for my $table (@arg_tables) {
 410                 for my $name (keys %$table) {
 411                         my $arg = $table->{$name};
 412                         defined($arg->{'var'}) || next;
 413                         defined($arg->{'pass'}) && !$arg->{'pass'} && !exists $overrides{$name} && next;
 414                         my $value;
 415                         if (!defined($value = $overrides{$name})) {
 416                                 if (exists $overrides{$name}) {
 417                                         $value = $arg->{'default'};
 418                                 } else {
 419                                         $value = ${$arg->{'var'}};
 420                                 }
 421                         }
 422                         if ($value ne $arg->{'default'}) {
 423                                 $out->{$name} = $value;
 424                         }
 425                 }
 426         }
 427         return $out;
 428 }
 429
 430 sub self_ref(@) {
 431         my $out = make_out_args(@_);
 432         return "?" . join(':', map { "$_=" . url_param_escape($out->{$_}) } sort keys %$out);
 433 }
 434
 435 sub self_form(@) {
 436         my $out = make_out_args(@_);
 437         return join('', map { "<input type=hidden name=$_ value='" . html_escape($out->{$_}) . "'>\n" } sort keys %$out);
 438 }
 439
 440 ### Cookies
 441
 442 sub set_cookie($$@) {
 443         #
 444         # Unfortunately, the support for the new cookie standard (RFC 2965) among
 445         # web browsers is still very scarce, so we are still using the old Netscape
 446         # specification.
 447         #
 448         # Usage: set_cookie(name, value, option => value...), where options are:
 449         #
 450         #       max-age         maximal age in seconds
 451         #       domain          domain name scope
 452         #       path            path name scope
 453         #       secure          if present, cookie applies only to SSL connections
 454         #                       (in this case, the value should be undefined)
 455         #       discard         if present with any value, the cookie is discarded
 456         #
 457
 458         my $key = shift @_;
 459         my $value = shift @_;
 460         my %other = @_;
 461         if (exists $other{'discard'}) {
 462                 delete $other{'discard'};
 463                 $other{'max-age'} = 0;
 464         }
 465         if (defined(my $age = $other{'max-age'})) {
 466                 delete $other{'max-age'};
 467                 my $exp = ($age ? (time + $age) : 0);
 468                 # Avoid problems with locales
 469                 my ($S,$M,$H,$d,$m,$y,$wd) = gmtime $exp;
 470                 my @wdays = ( 'Sun', 'Mon', 'Tue', 'Wed', 'Thu', 'Fri', 'Sat' );
 471                 my @mons = ( 'Jan', 'Feb', 'Mar', 'Apr', 'May', 'Jun', 'Jul', 'Aug', 'Sep', 'Oct', 'Nov', 'Dec' );
 472                 $other{'expires'} = sprintf("%s, %02d-%s-%d %02d:%02d:%02d GMT",
 473                         $wdays[$wd], $d, $mons[$m], $y+1900, $H, $M, $S);
 474         }
 475
 476         print "Set-Cookie: $key=", url_escape($value);
 477         foreach my $k (keys %other) {
 478                 print "; $k";
 479                 print "=", $other{$k} if defined $other{$k};
 480         }
 481         print "\n";
 482 }
 483
 484 sub parse_cookies() {
 485         my $h = http_get("Cookie") or return ();
 486         my @cook = ();
 487         foreach my $x (split /;\s*/, $h) {
 488                 my ($k,$v) = split /=/, $x;
 489                 $v = url_deescape($v) if defined $v;
 490                 push @cook, $k => $v;
 491         }
 492         return @cook;
 493 }
 494
 495 1;  # OK