show-switch

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use Net::SNMP ();
   6 use Net::Netmask;
   7 use Data::Dumper;
   8 use Getopt::Long;
   9 use List::Util;
  10
  11 no warnings 'uninitialized';
  12
  13 sub usage {
  14         die <<AMEN ;
  15 Usage: $0 [<options>] <ip-addr>
  16
  17 Options:
  18 --debug         Show debugging outputs
  19 --mac           Show one MAC address learned per port
  20 --allmac        Show all MAC addresses learned per port
  21 --force-v1      Use SNMPv1 (work-around for buggy switches)
  22 AMEN
  23 }
  24
  25 my $debug = 0;
  26 my $mac = 0;
  27 my $all_mac = 0;
  28 my $force_v1 = 0;
  29 GetOptions(
  30         'debug' => \$debug,
  31         'mac' => \$mac,
  32         'allmac' => \$all_mac,
  33         'force-v1' => \$force_v1,
  34 ) or usage;
  35
  36 @ARGV == 1 or usage;
  37 my ($switch_ip) = @ARGV;
  38 my $community = 'public';
  39 $mac ||= $all_mac;
  40
  41 my $is_tty = -t STDOUT;
  42 sub attr {
  43         my ($a) = @_;
  44         return $is_tty ? `tput $a` : "";
  45 }
  46 my $t_red = attr("setaf 1");
  47 my $t_green = attr("setaf 2");
  48 my $t_yellow = attr("setaf 3");
  49 my $t_magenta = attr("setaf 5");
  50 my $t_norm = attr("sgr0");
  51
  52 my ($snmp, $err) = Net::SNMP->session(
  53         -hostname => $switch_ip,
  54         -version => ($force_v1 ? '1' : '2c'),
  55         -community => $community,
  56 );
  57 $snmp or die "Cannot establish session: $err\n";
  58 $snmp->translate(0);
  59
  60 sub my_get_table {
  61         my ($cols) = @_;
  62         my $tab = {};
  63         for my $c (keys %$cols) {
  64                 my $depth = split /\./, $cols->{$c};
  65                 my $t = $snmp->get_table(-baseoid => $cols->{$c}) or next;
  66                 for my $k (keys %$t) {
  67                         my @k = split /\./, $k;
  68                         my $kk = join('.', @k[$depth..$#k]);
  69                         $tab->{$kk}->{$c} = $t->{$k};
  70                 }
  71         }
  72         return $tab;
  73 }
  74
  75 sub format_uptime {
  76         my ($t) = @_;
  77         my $d = "";
  78         $t = int($t/100);
  79         if ($t >= 86400) {
  80                 $d = int($t/86400) . " days, ";
  81                 $t %= 86400;
  82         }
  83         return $d . sprintf "%02d:%02d:%02d", int($t/3600), int(($t%3600)/60), $t%60;
  84 }
  85
  86 my $OID_basic = '1.3.6.1.2.1.1';
  87
  88 my $basics = my_get_table({
  89         'desc' => "$OID_basic.1",
  90         'uptime' => "$OID_basic.3",
  91         'contact' => "$OID_basic.4",
  92         'name' => "$OID_basic.5",
  93         'location' => "$OID_basic.6",
  94 });
  95 print Dumper($basics) if $debug;
  96 my $bas = $basics->{0} or die "Cannot find basic info";
  97 for (values %$bas) {
  98         s{\r}{}gs;
  99         s{\n}{ | }gs;
 100 }
 101
 102 print "### Basics ###\n\n";
 103 print "Device:   ", $bas->{desc}, "\n";
 104 print "Uptime:   ", format_uptime($bas->{uptime}), "\n";
 105 print "Contact:  ", $bas->{contact}, "\n";
 106 print "Name:     ", $bas->{name}, "\n";
 107 print "Location: ", $bas->{location}, "\n";
 108
 109 my $OID_ifTable = '1.3.6.1.2.1.2.2';
 110 my $OID_ifTablev2 = '1.3.6.1.2.1.31.1.1';
 111
 112 my $if_table = my_get_table({
 113         'desc' => "$OID_ifTable.1.2",
 114         'speed' => "$OID_ifTable.1.5",
 115         'mac' => "$OID_ifTable.1.6",
 116         'admin' => "$OID_ifTable.1.7",
 117         'oper' => "$OID_ifTable.1.8",
 118         'name' => "$OID_ifTablev2.1.1",
 119         'hispeed' => "$OID_ifTablev2.1.15",
 120         'alias' => "$OID_ifTablev2.1.18",
 121 });
 122 my %if_macs = ();
 123 for my $if (values %$if_table) {
 124         $if->{mac} = join(':', map { sprintf "%02x", ord $_ } split(//, $if->{mac}));
 125         $if_macs{$if->{mac}} = 1;
 126 }
 127 print Dumper($if_table) if $debug;
 128 my @ifaces = sort { $a <=> $b } keys %$if_table;
 129 print "MAC addr: ", join(" ", sort keys %if_macs), "\n";
 130
 131 my $OID_ipTable = '1.3.6.1.2.1.4.20';
 132 my $ip_table = my_get_table({
 133         'iface' => "$OID_ipTable.1.2",
 134         'mask' => "$OID_ipTable.1.3",
 135 });
 136 print Dumper($ip_table) if $debug;
 137
 138 # XXX: IPv6 not supported yet
 139 for my $ipa (keys %$ip_table) {
 140         my $ip = $ip_table->{$ipa};
 141         my $if = $if_table->{$ip->{iface}} or die "IP table refers to unknown iface";
 142         my $nm = Net::Netmask->new2($ipa, $ip->{mask}) or die "Cannot parse IP prefix";
 143         push @{$if->{ip_addrs}}, $ipa . '/' . $nm->bits;
 144 }
 145 print Dumper($if_table) if $debug;
 146
 147 if ($mac) {
 148         my $OID_1qTpFdbTable = '1.3.6.1.2.1.17.7.1.2.2';
 149         my $vlan_fdb_table = my_get_table({
 150                 'port' => "$OID_1qTpFdbTable.1.2",
 151                 'status' => "$OID_1qTpFdbTable.1.3",
 152         });
 153         print Dumper($vlan_fdb_table) if $debug;
 154
 155         if (%$vlan_fdb_table) {
 156                 for my $m (keys %$vlan_fdb_table) {
 157                         my $fdb = $vlan_fdb_table->{$m};
 158                         $fdb->{status} == 3 or next;    # Only learned MACs
 159                         my $port = $if_table->{$fdb->{port}} or die "Forwarding DB refers to unknown iface";
 160                         my @m = split /\./, $m;
 161                         my $vlan = shift @m;
 162                         my $mac = join(':', map { sprintf('%02x', $_) } @m);
 163                         push @{$port->{macs}}, $mac;
 164                 }
 165         } else {
 166                 print "# Trying fall-fack to .1d FDB\n" if $debug;
 167                 my $OID_1dTpFdbTable = '1.3.6.1.2.1.17.4.3';
 168                 my $fdb_table = my_get_table({
 169                         'port' => "$OID_1dTpFdbTable.1.2",
 170                         'status' => "$OID_1dTpFdbTable.1.3",
 171                 });
 172                 print Dumper($fdb_table) if $debug;
 173                 for my $m (keys %$fdb_table) {
 174                         my $fdb = $fdb_table->{$m};
 175                         $fdb->{status} == 3 or next;    # Only learned MACs
 176                         my $port = $if_table->{$fdb->{port}} or die "Forwarding DB refers to unknown iface";
 177                         my @m = split /\./, $m;
 178                         my $mac = join(':', map { sprintf('%02x', $_) } @m);
 179                         push @{$port->{macs}}, $mac;
 180                 }
 181         }
 182
 183         for my $if (values %$if_table) {
 184                 $if->{macs} or next;
 185                 $if->{macs} = [ sort(List::Util::uniq(@{$if->{macs}})) ];
 186         }
 187 }
 188
 189 my $OID_VlanStaticTable = '1.3.6.1.2.1.17.7.1.4.3';
 190 my $vlan_table = my_get_table({
 191         'name' => "$OID_VlanStaticTable.1.1",
 192         'egress-ports' => "$OID_VlanStaticTable.1.2",
 193         'untagged-ports' => "$OID_VlanStaticTable.1.4",
 194         'row-status' => "$OID_VlanStaticTable.1.5",
 195 });
 196 for my $vlan (values %$vlan_table) {
 197         for my $k ('egress-ports', 'untagged-ports') {
 198                 $vlan->{$k} = [ split //, unpack("B*", $vlan->{$k} // "") ];
 199         }
 200 }
 201 print Dumper($vlan_table) if $debug;
 202 my @vlans = sort { $a <=> $b } grep { $vlan_table->{$_}->{'row-status'} == 1 } keys %$vlan_table;
 203
 204 print "\n### VLANs ###\n\n";
 205 if (@vlans) {
 206         for my $vid (@vlans) {
 207                 printf "%-4d  %s\n", $vid, $vlan_table->{$vid}->{'name'} // '-';
 208         }
 209 } else {
 210         print "No VLAN support.\n";
 211 }
 212
 213 print "\n### Ports ###\n\n";
 214 # XXX: We assume that 802.1d switch ports IDs are equal to interface IDs
 215 for my $port (@ifaces) {
 216         my $if = $if_table->{$port};
 217         my $state;
 218         my $scolor = $t_norm;
 219         if ($if->{'admin'} != 1) {
 220                 $state = 'OFF';
 221         } elsif ($if->{'oper'} != 1) {
 222                 $state = 'DOWN';
 223                 $scolor = $t_red;
 224         } else {
 225                 $state = 'UP';
 226                 $scolor = $t_green;
 227         }
 228         my $speed = $if->{hispeed} || int($if->{speed} / 1000000);
 229         if (!$speed) {
 230                 $speed = "";
 231         } elsif ($speed < 1000) {
 232                 $speed = "${speed}M";
 233         } else {
 234                 $speed = int($speed/1000);
 235                 $speed = "${speed}G";
 236         }
 237         printf "%-4d %-15.15s  %s%-4s %-5s %s%-25.25s%s", $port, $if->{name}, $scolor, $state, $speed, $t_yellow, $if->{alias}, $t_norm;
 238
 239         if ($mac) {
 240                 my $show_mac = "";
 241                 my $more_macs = " ";
 242                 my @macs = @{$if->{macs} // []};
 243                 if (@macs) {
 244                         $show_mac = $macs[0];
 245                         $more_macs = "${t_yellow}+${t_norm}" if @macs > 1;
 246                 }
 247                 printf " %-17s%s ", $show_mac, $more_macs;
 248         }
 249
 250         for my $vid (@vlans) {
 251                 my $vlan = $vlan_table->{$vid};
 252                 if ($vlan->{'egress-ports'}->[$port]) {
 253                         if ($vlan->{'untagged-ports'}->[$port]) {
 254                                 if ($t_green ne "") {
 255                                         print " ${t_green}${vid}${t_norm}";
 256                                 } else {
 257                                         print " ${vid}U";
 258                                 }
 259                         } else {
 260                                 print " $vid";
 261                         }
 262                 }
 263         }
 264
 265         print "\n";
 266
 267         if ($if->{ip_addrs}) {
 268                 print "${t_yellow}     IP: ", join(" ", @{$if->{ip_addrs}}), "${t_norm}\n";
 269         }
 270         if ($all_mac) {
 271                 if ($if->{mac}) {
 272                         print "${t_yellow}     Local MAC: ", $if->{mac}, "${t_norm}\n";
 273                 }
 274                 if ($if->{macs}) {
 275                         for my $m (@{$if->{macs}}) {
 276                                 print "${t_magenta}     MAC: $m${t_norm}\n";
 277                         }
 278                 }
 279         }
 280 }