rs485-case/case.scad

   1 wall_thickness = 1.5;
   2
   3 pcb_length = 53.5;
   4 pcb_width = 18.5;
   5 pcb_thickness = 1;
   6 pcb_depth = 3;
   7 pcb_rail_width = 1;
   8
   9 box_height = 12;
  10 box_depth = pcb_thickness + pcb_depth;
  11
  12 usb_width = 10.5;
  13 usb_height = 11;
  14
  15 rs485_width = 16.5;
  16 rs485_height = 8;
  17
  18 text_depth = 0.2;
  19
  20 over = 0.1;
  21 clearance = 0.3;
  22
  23 module bottom() {
  24         difference() {
  25                 // Exterior
  26                 translate([-wall_thickness, -wall_thickness, -box_depth-wall_thickness])
  27                         cube([2*wall_thickness + pcb_length, 2*wall_thickness + pcb_width, wall_thickness + box_depth + box_height]);
  28
  29                 // Interior
  30                 cube([pcb_length, pcb_width, box_height+1]);
  31
  32                 // USB connector hole
  33                 translate([pcb_length-over, (pcb_width-usb_width)/2, 0])
  34                         cube([wall_thickness+2, usb_width, box_height+over]);
  35
  36                 // RS485 connector hole
  37                 translate([-wall_thickness-over, (pcb_width-rs485_width)/2, 0])
  38                         cube([wall_thickness+2*over, rs485_width, box_height+over]);
  39
  40                 // PCB
  41                 translate([0, 0, -pcb_thickness])
  42                         cube([pcb_length, pcb_width, pcb_thickness+over]);
  43
  44                 // Sub-PCB holes
  45                 translate([0, pcb_rail_width, -pcb_thickness-pcb_depth])
  46                         cube([10, pcb_width - 2*pcb_rail_width, pcb_thickness + pcb_depth + over]);
  47                 translate([24, pcb_rail_width, -pcb_thickness-pcb_depth])
  48                         cube([9, pcb_width - 2*pcb_rail_width, pcb_thickness + pcb_depth + over]);
  49                 translate([pcb_length - 9, pcb_rail_width, -pcb_thickness-pcb_depth])
  50                         cube([8, pcb_width - 2*pcb_rail_width, pcb_thickness + pcb_depth + over]);
  51         }
  52 }
  53
  54 module top() {
  55         difference() {
  56                 union() {
  57                         // Lid
  58                         translate([-wall_thickness, -wall_thickness, 0])
  59                                 cube([pcb_length + 2*wall_thickness, pcb_width + 2*wall_thickness, wall_thickness]);
  60
  61                         // USB connector roof
  62                         translate([pcb_length, (pcb_width - usb_width)/2 + clearance, usb_height - box_height + clearance])
  63                                 cube([wall_thickness, usb_width - 2*clearance, box_height - usb_height - clearance + over]);
  64
  65                         // RS485 connector roof
  66                         translate([-wall_thickness, (pcb_width - rs485_width)/2 + clearance, rs485_height - box_height + clearance])
  67                                 cube([wall_thickness, rs485_width - 2*clearance, box_height - rs485_height - clearance + over]);
  68                 }
  69
  70                 // LED holes
  71                 translate([32, 1, -over])
  72                         cube([4, 2, wall_thickness + 2*over]);
  73                 translate([32, pcb_width - 3, -over])
  74                         cube([4, 2, wall_thickness + 2*over]);
  75
  76                 // USB label
  77                 translate([pcb_length-3, pcb_width/2, wall_thickness - text_depth])
  78                 rotate(90)
  79                 scale([0.4, 0.4, 1])
  80                         linear_extrude(text_depth + over)
  81                         text("USB", font = "Liberation Serif", halign="center");
  82
  83                 // RS485 label
  84                 translate([3, pcb_width/2, wall_thickness - text_depth])
  85                 rotate(-90)
  86                 scale([0.4, 0.4, 1])
  87                         linear_extrude(text_depth + over)
  88                         text("RS 485", font = "Liberation Serif", halign="center");
  89         }
  90 }
  91
  92 color([0.7, 0, 0]) bottom();
  93 color([0, 1, 0]) translate([0, 0, box_height]) top();