m4/nsc.m4

   1 dnl ###
   2 dnl ### NSC -- Zone File Generator
   3 dnl ### (c) 1997--2003 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 dnl ### Usage: m4 nsc.m4 domain-source-files >zone-file -DVERS=path-to-version-file
   6 dnl ###
   7 include(m4/dnslib.m4)
   8
   9 # Version number
  10
  11 ifdef(`VERS',`',`nsc_fatal_error(`VERS macro not defined')')
  12
  13 define(TODAY_CODE, translit(esyscmd(`date +"%Y%m%d"'),`
  14 ',`'))
  15 sinclude(VERS)
  16 # Backward compatibility with NSC 2.x version files
  17 ifdef(`last_today_code', `define(`LAST_TODAY_CODE',last_today_code)undefine(`last_today_code')')
  18 ifdef(`subver_num', `define(`SUBVER_NUM',subver_num)undefine(`subver_num')')
  19 ifelse(TODAY_CODE, LAST_TODAY_CODE, `', `define(`SUBVER_NUM',1)')
  20 syscmd(echo >VERS "`define'(`LAST_TODAY_CODE',TODAY_CODE) `define'(`SUBVER_NUM',incr(SUBVER_NUM))")
  21 ifelse(eval(SUBVER_NUM > 99),1,`nsc_fatal_error(`Too many zone changes in a single day, you must tweak 'VERS` manually')')
  22 define(`VERSION',TODAY_CODE`'format(`%02d', SUBVER_NUM))
  23
  24 # Record names
  25
  26 define(nsc_set_name, `define(`CURRENT_NAME', nsc_corr_dot($1))define(`PRINT_NAME', CURRENT_NAME)')
  27 define(nsc_emit_name, `ifdef(`PRINT_NAME', `PRINT_NAME`'undefine(`PRINT_NAME')', `')')
  28 define(nsc_abs_name, `ifelse(CURRENT_NAME, translit(CURRENT_NAME,.,:), CURRENT_NAME.CURRENT_DOMAIN, CURRENT_NAME)')
  29
  30 # SOA record
  31
  32 define(nsc_SOA, `
  33 $ORIGIN CURRENT_DOMAIN
  34 $TTL    MINTTL
  35 nsc_emit_name   `SOA'   nsc_corr_dot(NSNAME) MAINTNAME (
  36                 VERSION REFRESH RETRY EXPIRE MINTTL )')
  37 define(SOA, `ifdef(`CURRENT_DOMAIN',`ifdef(`REVERSE_MODE',,`nsc_fatal_error(`SOA record defined twice')')')dnl
  38 define(`CURRENT_DOMAIN',$1.)dnl
  39 nsc_set_name(CURRENT_DOMAIN)dnl
  40 ifdef(`REVERSE_MODE',,`nsc_SOA')')
  41
  42 # Reverse zones
  43
  44 define(REVERSE, `divert(-1)
  45         define(`REVERSE_MODE', `')
  46         nsc_if_v6($1,`
  47                 define(`REVNET6', nsc_revblock6($1))
  48         ',`
  49                 define(`REVNET', `$1.')
  50                 define(`REVLOW', `$2')
  51                 define(`REVHIGH', `$3')
  52         ')
  53 ')
  54
  55 define(nsc_mk_PTR, `
  56         divert`'$1      `PTR'   $2
  57 divert(-1)
  58 ')
  59
  60 define(nsc_auto_PTR4, `dnl
  61 ifdef(`REVNET', `
  62         ifelse(REVNET, substr($1, 0, len(REVNET)), `
  63                 define(`REVX', substr($1, len(REVNET)))
  64                 ifelse(REVLOW, `',
  65                         `nsc_mk_PTR(nsc_revaddr(REVX), $2)',
  66                         `
  67                                 ifelse(eval((REVX >= REVLOW) && (REVX <= REVHIGH)), 1, `nsc_mk_PTR(REVX, $2)')
  68                         ')
  69                 ')
  70         ')dnl
  71 ')
  72
  73 define(nsc_auto_PTR6, `dnl
  74 ifdef(`REVNET6', `
  75         define(`REVA', nsc_revaddr6($1))
  76         ifelse(REVNET6, substr(REVA, eval(63-len(REVNET6))), `
  77                 nsc_mk_PTR(substr(REVA, 0, eval(62-len(REVNET6))), $2)
  78                 ')
  79         ')dnl
  80 ')
  81
  82 # A records
  83
  84 define(nsc_AONLY, `nsc_emit_name        nsc_if_v6($1,`AAAA      nsc_norm_v6($1)',``A'   $1')
  85 ')
  86 define(nsc_A, `nsc_if_v6($1,`nsc_auto_PTR6',`nsc_auto_PTR4')($1,nsc_abs_name)nsc_AONLY($1)')
  87 define(ADDR, `nsc_iterate(`nsc_A', $@)dnl')
  88 define(DADDR, `nsc_iterate(`nsc_AONLY', $@)dnl')
  89
  90 # Host specification
  91
  92 define(H, `nsc_set_name($1)nsc_iterate(`nsc_A', shift($@))dnl')
  93 define(DH, `nsc_set_name($1)nsc_iterate(`nsc_AONLY', shift($@))dnl')
  94
  95 # Subdomain specification and glue records
  96
  97 define(D, `nsc_set_name($1)dnl')
  98 define(GLUE, `DH($@)')
  99
 100 # NS record
 101
 102 define(nsc_NS, `nsc_emit_name   `NS'    nsc_corr_dot($1)
 103 ')
 104 define(NS, `nsc_iterate(`nsc_NS', $@)dnl')
 105
 106 # MX record
 107
 108 define(nsc_MX, `nsc_emit_name   `MX'    nsc_corr_dot($1)
 109 ')
 110 define(MX, `nsc_iterate(`nsc_MX', $@)dnl')
 111
 112 # HINFO record
 113
 114 define(HI, `nsc_emit_name       HINFO   "$1" "$2"')
 115
 116 # ALIASing records
 117
 118 define(nsc_ALIAS, `$1   `CNAME' CURRENT_NAME
 119 ')
 120 define(ALIAS, `nsc_iterate(`nsc_ALIAS', $@)nsc_set_name(CURRENT_NAME)dnl')
 121
 122 # CNAME records
 123
 124 define(CNAME, `$1       `CNAME' nsc_corr_dot($2)')
 125
 126 # Explicit PTR records
 127
 128 define(PTR, `$1 `PTR'   nsc_corr_dot($2)')
 129
 130 # Shortcut for classless reverse delegation of a block
 131
 132 define(REVBLOCK, `nsc_forloop(`i', $2, $3, `i'  `CNAME' `i'.$1
 133 )D($1)
 134 ')
 135
 136 # Cleanup actions
 137
 138 define(nsc_cleanup, `ifdef(`DISABLE_LOCALHOST',,`
 139 ; Added automatically (required by RFC 1912)
 140 localhost       A       127.0.0.1
 141 ')')
 142 m4wrap(`nsc_cleanup')
 143
 144 divert(0)dnl
 145 `;;;' Primary zone file
 146 `;;;' Generated by NSCVER (nsc.m4) on CURRENT_DATE
 147 `;;;' Please do not edit manually
 148 `'