m4/nsc.m4

   1 dnl ###
   2 dnl ### NSC -- Zone File Generator
   3 dnl ### (c) 1997--2011 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 dnl ### Usage: m4 -DVERS=path-to-version-file nsc.m4 domain-source-files >zone-file
   6 dnl ###
   7 include(m4/dnslib.m4)
   8
   9 # Version number
  10
  11 ifdef(`HASHING', `define(`VERSION',`YYYYMMDDNN')', `
  12
  13 ifdef(`VERS',`',`nsc_fatal_error(`VERS macro not defined')')
  14
  15 define(TODAY_CODE, translit(esyscmd(`date +"%Y%m%d"'),`
  16 ',`'))
  17 sinclude(VERS)
  18 # Backward compatibility with NSC 2.x version files
  19 ifdef(`last_today_code', `define(`LAST_TODAY_CODE',last_today_code)undefine(`last_today_code')')
  20 ifdef(`subver_num', `define(`SUBVER_NUM',subver_num)undefine(`subver_num')')
  21 ifelse(TODAY_CODE, LAST_TODAY_CODE, `', `define(`SUBVER_NUM',1)')
  22 syscmd(echo >VERS "`define'(`LAST_TODAY_CODE',TODAY_CODE) `define'(`SUBVER_NUM',incr(SUBVER_NUM))")
  23 ifelse(eval(SUBVER_NUM > 99),1,`nsc_fatal_error(`Too many zone changes in a single day, you must tweak 'VERS` manually')')
  24 define(`VERSION',TODAY_CODE`'format(`%02d', SUBVER_NUM))
  25
  26 ')
  27
  28 # Record names
  29
  30 define(nsc_set_name, `define(`CURRENT_NAME', nsc_corr_dot($1))define(`PRINT_NAME', CURRENT_NAME)')
  31 define(nsc_emit_name, `ifdef(`PRINT_NAME', `PRINT_NAME`'undefine(`PRINT_NAME')', `')')
  32 define(nsc_abs_name, `ifelse(CURRENT_NAME, translit(CURRENT_NAME,.,:), CURRENT_NAME.CURRENT_DOMAIN, CURRENT_NAME)')
  33
  34 # SOA record
  35
  36 define(nsc_SOA, `
  37 ifelse(CURRENT_DOMAIN,@,`',$ORIGIN CURRENT_DOMAIN)
  38 $TTL    MINTTL
  39 nsc_emit_name   `SOA'   nsc_corr_dot(NSNAME) MAINTNAME (
  40                 VERSION REFRESH RETRY EXPIRE MINTTL )')
  41 define(SOA, `ifdef(`CURRENT_DOMAIN',`ifdef(`REVERSE_MODE',,`nsc_fatal_error(`SOA record defined twice')')')dnl
  42 define(`CURRENT_DOMAIN',ifelse($1,@,@,$1.))dnl
  43 nsc_set_name(CURRENT_DOMAIN)dnl
  44 ifdef(`REVERSE_MODE',,`nsc_SOA')')
  45
  46 # Reverse zones
  47
  48 define(REVERSE, `divert(-1)
  49         define(`REVERSE_MODE', `')
  50         nsc_if_v6($1,`
  51                 define(`REVNET6', nsc_revblock6($1))
  52         ',`
  53                 define(`REVNET', `$1.')
  54                 define(`REVLOW', `$2')
  55                 define(`REVHIGH', `$3')
  56         ')
  57 ')
  58
  59 define(nsc_mk_PTR, `
  60         divert`'$1      `PTR'   $2
  61 divert(-1)
  62 ')
  63
  64 define(nsc_auto_PTR4, `dnl
  65 ifdef(`REVNET', `
  66         ifelse(REVNET, substr($1, 0, len(REVNET)), `
  67                 define(`REVX', substr($1, len(REVNET)))
  68                 ifelse(REVLOW, `',
  69                         `nsc_mk_PTR(nsc_revaddr(REVX), $2)',
  70                         `
  71                                 ifelse(eval((REVX >= REVLOW) && (REVX <= REVHIGH)), 1, `nsc_mk_PTR(REVX, $2)')
  72                         ')
  73                 ')
  74         ')dnl
  75 ')
  76
  77 define(nsc_auto_PTR6, `dnl
  78 ifdef(`REVNET6', `
  79         define(`REVA', nsc_revaddr6($1))
  80         ifelse(REVNET6, substr(REVA, eval(63-len(REVNET6))), `
  81                 nsc_mk_PTR(substr(REVA, 0, eval(62-len(REVNET6))), $2)
  82                 ')
  83         ')dnl
  84 ')
  85
  86 # A records
  87
  88 define(nsc_AONLY, `nsc_emit_name        nsc_if_v6($1,`AAAA      nsc_norm_v6($1)',``A'   $1')
  89 ')
  90 define(nsc_A, `nsc_if_v6($1,`nsc_auto_PTR6',`nsc_auto_PTR4')($1,nsc_abs_name)nsc_AONLY($1)')
  91 define(ADDR, `nsc_iterate(`nsc_A', $@)dnl')
  92 define(DADDR, `nsc_iterate(`nsc_AONLY', $@)dnl')
  93
  94 # Host specification
  95
  96 define(H, `nsc_set_name($1)nsc_iterate(`nsc_A', shift($@))dnl')
  97 define(DH, `nsc_set_name($1)nsc_iterate(`nsc_AONLY', shift($@))dnl')
  98
  99 # Subdomain specification and glue records
 100
 101 define(D, `nsc_set_name($1)dnl')
 102 define(GLUE, `DH($@)')
 103
 104 # NS record
 105
 106 define(nsc_NS, `nsc_emit_name   `NS'    nsc_corr_dot($1)
 107 ')
 108 define(NS, `nsc_iterate(`nsc_NS', $@)dnl')
 109
 110 # MX record
 111
 112 define(nsc_MX, `nsc_emit_name   `MX'    nsc_corr_dot($1)
 113 ')
 114 define(MX, `nsc_iterate(`nsc_MX', $@)dnl')
 115
 116 # HINFO record
 117
 118 define(HI, `nsc_emit_name       HINFO   "$1" "$2"')
 119
 120 # ALIASing records
 121
 122 define(nsc_ALIAS, `$1   `CNAME' CURRENT_NAME
 123 ')
 124 define(ALIAS, `nsc_iterate(`nsc_ALIAS', $@)nsc_set_name(CURRENT_NAME)dnl')
 125
 126 # TXT records
 127
 128 define(TXT, `nsc_emit_name      `TXT'   "$1"')
 129
 130 # RP (responsible person) records
 131
 132 define(RP, `nsc_emit_name       `RP'    nsc_corr_dot($1) nsc_corr_dot($2)')
 133
 134 # SRV records
 135
 136 define(SRV, `_`'$1`'._`'$2`'.CURRENT_NAME       `SRV'   $3 $4 $5 nsc_corr_dot($6)`'nsc_set_name(CURRENT_NAME)')
 137
 138 # CNAME records
 139
 140 define(CNAME, `$1       `CNAME' nsc_corr_dot($2)')
 141
 142 # Explicit PTR records
 143
 144 define(PTR, `$1 `PTR'   nsc_corr_dot($2)')
 145
 146 # Shortcut for classless reverse delegation of a block
 147
 148 define(REVBLOCK, `nsc_forloop(`i', $2, $3, `i'  `CNAME' `i'.$1
 149 )D($1)
 150 ')
 151
 152 # Cleanup actions
 153
 154 define(nsc_cleanup, `ifdef(`DISABLE_LOCALHOST',,`
 155 ; Added automatically (required by RFC 1912)
 156 localhost       A       127.0.0.1
 157 ')')
 158 m4wrap(`nsc_cleanup')
 159
 160 divert(0)dnl
 161 `;;;' Primary zone file
 162 `;;;' Generated by NSCVER (nsc.m4) on ifdef(`HASHING', ``CURRENT_DATE'', `CURRENT_DATE')
 163 `;;;' Please do not edit manually
 164 `;;;' `VERSION': VERSION
 165 `'