m4/mkmf.m4

   1 dnl ###
   2 dnl ### NSC -- Makefile Builder
   3 dnl ### (c) 1997--2011 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 include(m4/dnslib.m4)
   6
   7 # Definition of primary domains; secondaries we needn't take care of
   8
   9 define(`PRIMARIES', `')
  10
  11 define(`nsc_prepend_cf_one', ` 'CFDIR/`nsc_file_name($1)')
  12 define(`nsc_prepend_cf_multi', `nsc_iterate(`nsc_prepend_cf_one', $@)')
  13 define(`PRIMARY', `divert(0)ZONEDIR/nsc_file_name($1):nsc_prepend_cf_multi($@) $(DDEPS)
  14         @bin/genzone nsc_file_name($1)`'nsc_prepend_cf_multi($@)
  15
  16 divert(-1)
  17 define(`PRIMARIES', PRIMARIES ZONEDIR/nsc_file_name($1))
  18 ')
  19
  20 define(`REVERSE', `PRIMARY(nsc_if_v6($1,`nsc_revblock6($1)',`nsc_revaddr($1)'), shift($@))')
  21
  22 define(`BLACKHOLE', `define(`NEED_BLACKHOLE', 1)')
  23
  24 # Insertion of raw makefile material
  25
  26 define(`MAKEFILE', `divert(0)$1
  27 divert(-1)')
  28
  29 # Last words
  30
  31 define(`nsc_cleanup', `
  32 ifdef(`NEED_BLACKHOLE', `PRIMARY(blackhole)')
  33
  34 divert(0)dnl
  35 VERSDIR/.version: CFDIR/domains ROOTCACHE`'PRIMARIES`'ifdef(`NEED_BLACKHOLE',` ZONEDIR/blackhole')
  36         NAMED_RESTART_CMD
  37         touch VERSDIR/.version
  38
  39 clean:
  40         find BAKDIR ZONEDIR HASHDIR DSSDIR -maxdepth 1 -type f | xargs rm -f
  41
  42 clobber: clean
  43         rm -f Makefile named.conf bin/shell-env
  44
  45 distclean: clobber
  46         find VERSDIR -maxdepth 1 -type f | xargs rm -f
  47 ')
  48
  49 divert(0)dnl
  50 `#'
  51 `#'     Nameserver Configuration Makefile
  52 `#'     Generated by NSCVER (mkmf.m4) on CURRENT_DATE
  53 `#'     Please don't edit manually
  54 `#'
  55
  56 DDEPS=m4/nsc.m4 m4/dnslib.m4 cf/config
  57
  58 all: VERSDIR/.version
  59 m4wrap(`nsc_cleanup')
  60 divert(-1)