m4/mkmf.m4

   1 dnl ###
   2 dnl ### NSC -- Makefile Builder
   3 dnl ### (c) 1997--2019 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 include(m4/dnslib.m4)
   6
   7 # Definition of primary domains; secondaries we needn't take care of
   8
   9 define(`PRIMARIES', `')
  10
  11 define(`nsc_prepend_cf_one', ` 'CFDIR/`nsc_file_name($1)')
  12 define(`nsc_prepend_cf_multi', `nsc_iterate(`nsc_prepend_cf_one', $@)')
  13 define(`nsc_key_dep', `ifelse(USE_DNSSEC,,,` 'khash/$1 khash/resign-stamp)')
  14 define(`PRIMARY', `divert(0)zone/nsc_file_name($1):nsc_prepend_cf_multi($@)nsc_key_dep($1) $(DDEPS)
  15         @bin/genzone nsc_file_name($1)`'nsc_prepend_cf_multi($@)
  16
  17 divert(-1)
  18 define(`PRIMARIES', PRIMARIES zone/nsc_file_name($1))
  19 ')
  20
  21 define(`REVERSE', `PRIMARY(nsc_if_v6($1,`nsc_revblock6($1)',`nsc_revaddr($1)'), shift($@))')
  22
  23 define(`BLACKHOLE', `define(`NEED_BLACKHOLE', 1)')
  24
  25 # Insertion of raw makefile material
  26
  27 define(`MAKEFILE', `divert(0)$1
  28 divert(-1)')
  29
  30 # Last words
  31
  32 define(`nsc_cleanup', `
  33 ifdef(`NEED_BLACKHOLE', `PRIMARY(blackhole)')
  34
  35 divert(0)dnl
  36 ver/.version: CFDIR/domains ROOTCACHE`'PRIMARIES`'ifdef(`NEED_BLACKHOLE',` zone/blackhole')
  37         NAMED_RESTART_CMD
  38         touch ver/.version
  39
  40 clean:
  41         find bak zone hash -maxdepth 1 -type f | xargs rm -f
  42
  43 clobber: clean
  44         rm -f Makefile named.conf bin/shell-env
  45
  46 distclean: clobber
  47         find ver -maxdepth 1 -type f | xargs rm -f
  48 ')
  49
  50 divert(0)dnl
  51 `#'
  52 `#'     Nameserver Configuration Makefile
  53 `#'     Generated by NSCVER (mkmf.m4) on CURRENT_DATE
  54 `#'     Please don't edit manually
  55 `#'
  56
  57 DDEPS=m4/nsc.m4 m4/dnslib.m4 cf/config
  58
  59 all: ver/.version
  60 m4wrap(`nsc_cleanup')
  61 divert(-1)