m4/mkmf.m4

   1 dnl ###
   2 dnl ### NSC -- Makefile Builder
   3 dnl ### (c) 1997--2003 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 include(m4/dnslib.m4)
   6
   7 # Definition of primary domains; secondaries we needn't take care of
   8
   9 define(`PRIMARIES', `')
  10
  11 define(`nsc_prepend_cf_one', ` 'CFDIR/`$1')
  12 define(`nsc_prepend_cf_multi', `nsc_iterate(`nsc_prepend_cf_one', $@)')
  13 define(`PRIMARY', `divert(0)ZONEDIR/$1:nsc_prepend_cf_multi($@) $(DDEPS)
  14         `$'(NSC)nsc_prepend_cf_multi($@) >ZONEDIR/$1 -DVERS=VERSDIR/$1
  15
  16 divert(-1)
  17 define(`PRIMARIES', PRIMARIES ZONEDIR/$1)
  18 ')
  19
  20 define(`REVERSE', `PRIMARY(nsc_if_v6($1,`nsc_revblock6($1)',`nsc_revaddr($1)'), shift($@))')
  21
  22 # Insertion of raw makefile material
  23
  24 define(`MAKEFILE', `divert(0)$1
  25 divert(-1)')
  26
  27 # Last words
  28
  29 define(`nsc_cleanup', `divert(0)VERSDIR/.version: CFDIR/domains ROOTCACHE`'PRIMARIES
  30         NAMED_RESTART_CMD
  31         touch VERSDIR/.version
  32
  33 clean:
  34         find BAKDIR ZONEDIR -type f -maxdepth 1 | xargs rm -f
  35
  36 clobber: clean
  37         rm -f Makefile named.conf
  38
  39 distclean: clobber
  40         find VERSDIR -type f -maxdepth 1 | xargs rm -f
  41 ')
  42
  43 divert(0)dnl
  44 `#'
  45 `#'     Nameserver Configuration Makefile
  46 `#'     Generated by NSCVER (mkmf.m4) on CURRENT_DATE
  47 `#'     Please don't edit manually
  48 `#'
  49
  50 `M4'=M4
  51 NSC=$(`M4') m4/nsc.m4
  52 DDEPS=m4/nsc.m4 m4/dnslib.m4 cf/config
  53
  54 all: VERSDIR/.version
  55 m4wrap(`nsc_cleanup')
  56 divert(-1)