m4/mkconf.m4

   1 dnl ###
   2 dnl ### NSC 2.2 -- BIND Config File Builder
   3 dnl ### (c) 1997--1999 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5
   6 # Definition of primary domain
   7
   8 define(`PRIMARY', `divert(0)zone "$1" in {
   9         type master;
  10         file "ZONEDIR/$1";
  11 };
  12
  13 divert(-1)')
  14
  15 # Definition of secondary domain
  16
  17 define(`SECONDARY', `divert(0)zone "$1" in {
  18         type slave;
  19         file "BAKDIR/$1";
  20         masters { $2; };
  21 };
  22
  23 divert(-1)')
  24
  25 # Definition of reverse domain
  26
  27 define(`REVERSE', `divert(0)zone "revaddr($1).in-addr.arpa" in {
  28         type master;
  29         file "ZONEDIR/revaddr($1)";
  30 };
  31
  32 divert(-1)')
  33
  34 # Definition of reverse sub-domain
  35
  36 define(`PARTIAL', `SECONDARY(revaddr($1).in-addr.arpa,$3)')
  37 define(`PREVERSE', `REVERSE($1)')
  38
  39 # Definition of forwarders for both normal and slave mode
  40
  41 define(`FORWard', `patsubst(`$@',`,',`; ')')
  42 define(`FORWArd', `divert(0)    forward $1;
  43         forwarders { FORWard(shift($@),)};
  44 divert(-1)')
  45
  46 define(`FORWARD', `FORWArd(first, $@)')
  47 define(`SLAVE', `FORWArd(only, $@)')
  48
  49 divert(-1)')
  50
  51 # Manual insertion of config file material
  52
  53 define(`CONFIG', `divert(0)$1
  54 divert(-1)')
  55
  56 # BIND options
  57
  58 define(`OPTIONS', `divert(0)options {
  59         directory "ROOT";
  60         interface-interval 0;
  61 $1};
  62
  63 zone "." in {
  64         type hint;
  65         file "root.cache";
  66 };
  67
  68 divert(-1)')
  69
  70 divert(0)dnl
  71 `#'
  72 `#'     Name server configuration file
  73 `#'     Generated by mkconf.m4 on curdate
  74 `#'     Please don't edit manually
  75 `#'
  76
  77 divert(-1)