m4/dnslib.m4

   1 dnl ###
   2 dnl ### NSC -- Library Functions For DNS Processing
   3 dnl ### (c) 1997--2008 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 divert(-1)
   6
   7 # NSC version
   8
   9 define(`NSCVER', `NSC 3.1')
  10
  11 # Current date and time
  12
  13 define(`CURRENT_DATE', translit(esyscmd(`date'),`
  14 ',`'))
  15
  16 # Time conversion
  17
  18 define(MINUTES, `eval($1*60)')
  19 define(HOURS, `eval($1*3600)')
  20 define(DAYS, `eval($1*86400)')
  21
  22 # Since slashes can occur in zone names, we convert them to @'s
  23
  24 define(nsc_file_name, `translit($1,/,@)')
  25
  26 # Reverse an IP address
  27
  28 define(nsc_revIPa, `ifelse($#, 1, `$1', `nsc_revIPa(shift($@)).$1')')
  29 define(nsc_revaddr, `nsc_revIPa(translit($1, `.', `,'))')
  30
  31 # Fix up dots in a name: if the name is not simple (i.e., it contains at least one dot),
  32 # ensure that it ends with a dot.
  33
  34 define(nsc_corr_dot, `ifelse(substr($1,decr(len($1))),.,$1,$1`'ifelse(index($1,.),-1,,.))')
  35
  36 # Normalize IPv6 address
  37
  38 define(nsc_if_v6, `ifelse(index($1,:),-1,`$3',`$2')')
  39
  40 define(nsc_norm_v6, `nsc_norm_v6_z(ifelse(regexp($1,`::.*::'),-1,`ifelse(index($1,::),-1,`nsc_norm_v6_nn($1)',`nsc_norm_v6_cc($1)')',`nsc_bad_v6($1)'))')
  41 # If there is no ::, check the number of :'s
  42 define(nsc_norm_v6_nn, `ifelse(nsc_extract_colons($1),:::::::,$1,`nsc_bad_v6($1)')')
  43 # Replace :: by the right number of :'s to get 8 (possibly empty) components
  44 define(nsc_norm_v6_cc, `regexp($1,`\(.*\)::\(.*\)',`\1'nsc_n_times(eval(9-len(nsc_extract_colons($1))),:)`\2')')
  45 # Delete everything except colons
  46 define(nsc_extract_colons, `ifelse(index($1,:),-1,,`:nsc_extract_colons(regexp($1,`\(.*\):\(.*\)',`\1\2'))')')
  47 # Repeat a given string N times
  48 define(nsc_n_times, `ifelse($1,0,,`$2`'nsc_n_times(eval($1-1),`$2')')')
  49 # Pad each component to 4 hex digits and convert them to lowercase
  50 define(nsc_norm_v6_z, `nsc_norm_v6_digs(translit($1,:,`,'))')
  51 define(nsc_norm_v6_digs, `nsc_norm_v6_dig($1)`'ifelse($#,1,,:`nsc_norm_v6_digs(shift($@))')')
  52 define(nsc_norm_v6_dig, `ifelse(eval(len($1) > 4),1,`nsc_bad_v6($1)',`nsc_n_times(eval(4-len($1)),0)`'translit($1,A-F,a-f)')')
  53 # Report a fatal error in IPv6 address
  54 define(nsc_bad_v6, `nsc_fatal_error(`Invalid IPv6 address: '$1)')
  55
  56 # Reverse an IPv6 address or block
  57
  58 define(nsc_revaddr6, `substr(nsc_do_revaddr6(nsc_norm_v6($1)),1)')
  59 define(nsc_do_revaddr6, `ifelse($1,,,substr($1,0,1),:,`nsc_do_revaddr6(substr($1,1))',`nsc_do_revaddr6(substr($1,2)).substr($1,1,1).substr($1,0,1)')')
  60 define(nsc_revblock6, `nsc_do_revblock6(translit($1,/,`,'))')
  61 define(nsc_do_revblock6, `substr(nsc_revaddr6($1),dnl
  62 ifelse(eval($2%4),0,`eval(64-$2/2)',`nsc_fatal_error(`Prefixes must respect hex digit boundary')'))')
  63
  64 # Iteration
  65
  66 define(nsc_itera, `ifelse($1,,,`nsc_iter($1)')`'ifelse($#,1,,`nsc_itera(shift($@))')')
  67 define(nsc_iterate, `define(`nsc_iter', defn(`$1'))nsc_itera(shift($@))')
  68
  69 # Generate name of reverse domain
  70
  71 define(REV, `nsc_if_v6($1,`nsc_revblock6($1).ip6.arpa',`nsc_revaddr($1).in-addr.arpa')')
  72
  73 # A for loop macro from m4 doc
  74
  75 define(`nsc_forloop',
  76    `pushdef(`$1', `$2')nsc__forloop(`$1', `$2', `$3', `$4')popdef(`$1')')
  77 define(`nsc__forloop',
  78    `$4`'ifelse($1, `$3', ,
  79    `define(`$1', incr($1))nsc__forloop(`$1', `$2', `$3', `$4')')')
  80
  81 # Reporting errors
  82
  83 define(`nsc_fatal_error', `errprint(`NSC error: $1
  84 ')m4exit(1)')
  85
  86 # Default values of parameters
  87
  88 define(`NAMED_RESTART_CMD', `ndc reload')
  89
  90 define(`ROOT', `/etc/named')
  91 define(`CFDIR', `cf')
  92 define(`ZONEDIR', `zone')
  93 define(`BAKDIR', `bak')
  94 define(`VERSDIR', `ver')
  95 define(`HASHDIR', `hash')
  96 define(`ROOTCACHE', `root.cache')
  97
  98 define(`REFRESH', HOURS(8))
  99 define(`RETRY', HOURS(2))
 100 define(`EXPIRE', DAYS(14))
 101 define(`MINTTL', DAYS(1))
 102 define(`NSNAME', translit(esyscmd(`hostname -f'),`
 103 ',`'))
 104 define(`MAINTNAME', `root'.`nsc_corr_dot(NSNAME)')
 105
 106 # And finally we change comments to semicolons to be compatible with the zone files
 107
 108 changecom(;)
 109
 110 ; User-defined parts of configuration
 111
 112 include(CFDIR/config)