m4/dnslib.m4

   1 dnl ###
   2 dnl ### NSC -- Library Functions For DNS Processing
   3 dnl ### (c) 1997--2019 Martin Mares <mj@ucw.cz>
   4 dnl ###
   5 divert(-1)
   6
   7 # NSC version
   8
   9 define(`NSCVER', `NSC 5.0')
  10
  11 # Current date and time
  12
  13 define(`CURRENT_DATE', translit(esyscmd(`date'),`
  14 ',`'))
  15
  16 # Time conversion
  17
  18 define(MINUTES, `eval($1*60)')
  19 define(HOURS, `eval($1*3600)')
  20 define(DAYS, `eval($1*86400)')
  21
  22 # Since slashes can occur in zone names, we convert them to @'s
  23
  24 define(nsc_file_name, `translit($1,/,@)')
  25
  26 # Reverse an IP address
  27
  28 define(nsc_revIPa, `ifelse($#, 1, `$1', `nsc_revIPa(shift($@)).$1')')
  29 define(nsc_revaddr, `nsc_revIPa(translit($1, `.', `,'))')
  30
  31 # Fix up dots in a name: If the name is not simple (i.e., it contains at least one unescaped
  32 # dot), ensure that it ends with a dot. Then unescape all escaped dots (\.).
  33
  34 define(nsc_name, `nsc_unescape_name(ifelse(substr($1,decr(len($1))),.,$1,$1`'ifelse(regexp($1,`[^\\]\.'),-1,,.)))')
  35 define(nsc_unescape_name,`patsubst(`$1',\\\.,.)')
  36
  37 # Normalize IPv6 address
  38
  39 define(nsc_if_v6, `ifelse(index($1,:),-1,`$3',`$2')')
  40
  41 define(nsc_norm_v6, `nsc_norm_v6_z(ifelse(regexp($1,`::.*::'),-1,`ifelse(index($1,::),-1,`nsc_norm_v6_nn($1)',`nsc_norm_v6_cc($1)')',`nsc_bad_v6($1)'))')
  42 # If there is no ::, check the number of :'s
  43 define(nsc_norm_v6_nn, `ifelse(nsc_extract_colons($1),:::::::,$1,`nsc_bad_v6($1)')')
  44 # Replace :: by the right number of :'s to get 8 (possibly empty) components
  45 define(nsc_norm_v6_cc, `regexp($1,`\(.*\)::\(.*\)',`\1'nsc_n_times(eval(9-len(nsc_extract_colons($1))),:)`\2')')
  46 # Delete everything except colons
  47 define(nsc_extract_colons, `ifelse(index($1,:),-1,,`:nsc_extract_colons(regexp($1,`\(.*\):\(.*\)',`\1\2'))')')
  48 # Repeat a given string N times
  49 define(nsc_n_times, `ifelse($1,0,,`$2`'nsc_n_times(eval($1-1),`$2')')')
  50 # Pad each component to 4 hex digits and convert them to lowercase
  51 define(nsc_norm_v6_z, `nsc_norm_v6_digs(translit($1,:,`,'))')
  52 define(nsc_norm_v6_digs, `nsc_norm_v6_dig($1)`'ifelse($#,1,,:`nsc_norm_v6_digs(shift($@))')')
  53 define(nsc_norm_v6_dig, `ifelse(eval(len($1) > 4),1,`nsc_bad_v6($1)',`nsc_n_times(eval(4-len($1)),0)`'translit($1,A-F,a-f)')')
  54 # Report a fatal error in IPv6 address
  55 define(nsc_bad_v6, `nsc_fatal_error(`Invalid IPv6 address: '$1)')
  56
  57 # Reverse an IPv6 address or block
  58
  59 define(nsc_revaddr6, `substr(nsc_do_revaddr6(nsc_norm_v6($1)),1)')
  60 define(nsc_do_revaddr6, `ifelse($1,,,substr($1,0,1),:,`nsc_do_revaddr6(substr($1,1))',`nsc_do_revaddr6(substr($1,2)).substr($1,1,1).substr($1,0,1)')')
  61 define(nsc_revblock6, `nsc_do_revblock6(translit($1,/,`,'))')
  62 define(nsc_do_revblock6, `substr(nsc_revaddr6($1),dnl
  63 ifelse(eval($2%4),0,`eval(64-$2/2)',`nsc_fatal_error(`Prefixes must respect hex digit boundary')'))')
  64
  65 # Iteration
  66
  67 define(nsc_itera, `ifelse($1,,,`nsc_iter($1)')`'ifelse($#,1,,`nsc_itera(shift($@))')')
  68 define(nsc_iterate, `define(`nsc_iter', defn(`$1'))nsc_itera(shift($@))')
  69
  70 # Generate name of reverse domain
  71
  72 define(REV, `nsc_if_v6($1,`nsc_revblock6($1).ip6.arpa',`nsc_revaddr($1).in-addr.arpa')')
  73
  74 # DNSSEC wrapper
  75
  76 define(`USE_DNSSEC')
  77 define(`DNSSEC', `define(`USE_DNSSEC',1)$1define(`USE_DNSSEC')')
  78
  79 # A for loop macro from m4 doc
  80
  81 define(`nsc_forloop',
  82    `pushdef(`$1', `$2')nsc__forloop(`$1', `$2', `$3', `$4')popdef(`$1')')
  83 define(`nsc__forloop',
  84    `$4`'ifelse($1, `$3', ,
  85    `define(`$1', incr($1))nsc__forloop(`$1', `$2', `$3', `$4')')')
  86
  87 # Reporting errors
  88
  89 define(`nsc_fatal_error', `errprint(`NSC error: $1
  90 ')m4exit(1)')
  91
  92 # Default values of parameters
  93
  94 define(`NAMED_RESTART_CMD', `rndc reload')
  95
  96 define(`CFDIR', `cf')
  97 define(`VERSDIR', `ver')
  98
  99 define(`REFRESH', HOURS(8))
 100 define(`RETRY', HOURS(2))
 101 define(`EXPIRE', DAYS(14))
 102 define(`MINTTL', DAYS(1))
 103 define(`NSNAME', translit(esyscmd(`hostname -f'),`
 104 ',`'))
 105 define(`MAINTNAME', `root'.`nsc_corr_dot(NSNAME)')
 106
 107 define(`KEYGEN_OPTIONS', `-a RSASHA256 -b 1024')
 108 define(`SIGNZONE_OPTIONS', `-e +'DAYS(365))
 109 define(`DSFROMKEY_OPTIONS', `')
 110
 111 # And finally we change comments to semicolons to be compatible with the zone files
 112
 113 changecom(;)
 114
 115 ; User-defined parts of configuration
 116
 117 include(CFDIR/config)