lib/bin/bex-prun

   1 #!/usr/bin/perl
   2 # Batch EXecutor 3.0 -- Parallel Execution Using Screen
   3 # (c) 2011-2012 Martin Mares <mj@ucw.cz>
   4
   5 use strict;
   6 use warnings;
   7 use feature 'switch';
   8 use Getopt::Long;
   9 use POSIX;
  10 use BEX;
  11
  12 my $queue_name;
  13 my $text_mode;
  14 my $debug;
  15 my $debug_children;
  16
  17 sub usage() {
  18         print <<AMEN ;
  19 Usage: bex prun [<options>] [[!]<machine-or-class> ...]
  20
  21 Options:
  22     --debug             Log status changes to stderr
  23     --debug-children    Log stdout and stderr of child processes to ./debug.log
  24 -p, --parallel=<n>      Set limit on the number of jobs run in parallel
  25 -q, --queue=<name>      Run jobs in the given queue
  26     --text              Use plain-text user interface instead of curses
  27 AMEN
  28         exit 0;
  29 }
  30
  31 GetOptions(
  32         "q|queue=s" => \$queue_name,
  33         "text!" => \$text_mode,
  34         "debug!" => \$debug,
  35         "debug-children!" => \$debug_children,
  36         "p|parallel=i" => \$BEX::Config::max_parallel_jobs,
  37         "help" => \&usage,
  38 ) or die "Try `bex prun --help' for more information.\n";
  39
  40 system 'tmux', 'has-session';
  41 !$? or die "You need to start tmux first.\n";
  42
  43 my $queue = BEX::Queue->new($queue_name);
  44 my $fifo_name = $queue->{'Path'} . '/status-fifo';
  45 unlink $fifo_name;
  46 mkfifo $fifo_name, 0700 or die "Cannot create $fifo_name: $!";
  47 open FIFO, '+<', $fifo_name or die "Cannot open $fifo_name: $!";
  48
  49 my $ui = ($text_mode ? BEX::bprun::text->new : BEX::bprun::curses->new);
  50
  51 my @machines = ();
  52 for my $mach (BEX::Config::parse_machine_list(@ARGV ? @ARGV : '*')) {
  53         my @jobs = $queue->scan($mach);
  54         @jobs or next;
  55         push @machines, $mach;
  56         for (@jobs) { $ui->update($mach, $_, 'READY'); }
  57 }
  58
  59 my %running = ();
  60 my $max = $BEX::Config::max_parallel_jobs;
  61
  62 while (keys %running || @machines) {
  63         if (@machines && keys %running < $max) {
  64                 my $mach = shift @machines;
  65                 $ui->update($mach, undef, 'START');
  66                 my @tm = ('tmux', 'new-window', '-n', $mach, '-d');
  67                 my $P5LIB = $ENV{"PERL5LIB"} // "";
  68                 my @cmd = (
  69                         "BEX_HOME='$BEX::Config::home'",
  70                         "BEX_LIB='$BEX::Config::lib'",
  71                         "PERL5LIB='$P5LIB'",
  72                         "$BEX::Config::lib/bin/bex-run",
  73                         "--status-fifo=$fifo_name",
  74                         "--queue=" . $queue->{'Name'},
  75                         $mach,
  76                         );
  77                 push @cmd, ">>debug.log", "2>&1" if $debug_children;
  78                 push @tm, join(" ", @cmd);
  79                 system @tm;
  80                 !$? or $ui->update($mach, undef, 'INTERR');
  81                 $running{$mach} = 'START';
  82                 next;
  83         }
  84         $_ = <FIFO>;
  85         chomp;
  86         print STDERR "<< $_\n" if $debug;
  87         my ($mach, $jid, $stat) = /^! (\S+) (\S+) (\S+)$/;
  88         if (!defined $stat) {
  89                 $ui->err("Received invalid status message <$_>");
  90                 next;
  91         }
  92         if (!defined $running{$mach}) {
  93                 $ui->err("Received status message <$_> for a machine which does not run");
  94                 next;
  95         }
  96         $running{$mach} = $stat;
  97         $ui->update($mach, ($jid eq '-' ? undef : $jid), $stat);
  98         if ($stat eq 'DONE') {
  99                 delete $running{$mach};
 100         }
 101 }
 102
 103 close FIFO;
 104 unlink $fifo_name;
 105 $ui->done;
 106
 107 package BEX::bprun::text;
 108
 109 sub new($) {
 110         return bless {};
 111 }
 112
 113 sub done($) {
 114 }
 115
 116 sub update($$$$) {
 117         my ($ui, $mach, $jid, $stat) = @_;
 118         print +($mach // '-'), (defined($jid) ? ":$jid" : ""), " $stat\n";
 119 }
 120
 121 sub err($$) {
 122         my ($ui, $msg) = @_;
 123         print STDERR "ERROR: $msg\n";
 124 }
 125
 126 package BEX::bprun::curses;
 127
 128 use Curses;
 129
 130 my $C;
 131
 132 my $nrows;
 133 my @by_row;
 134 my %by_host;
 135
 136 my %host_state;
 137 my %host_cnt;
 138
 139 my %job_state;
 140 my %job_cnt;
 141
 142 my %host_last_fail_job;
 143 my %host_last_fail_stat;
 144
 145 my @states;
 146 my %state_to_pri;
 147
 148 BEGIN {
 149         @by_row = ();
 150         %by_host = ();
 151         @states = qw(unknown ready running done failed);
 152         %state_to_pri = (
 153                 'unknown' => 0,
 154                 'ready' => 1,
 155                 'done' => 2,
 156                 'failed' => 3,
 157                 'running' => 4,
 158         );
 159 }
 160
 161 sub new($) {
 162         $C = new Curses;
 163         start_color;
 164         has_colors && COLORS >= 8 && COLOR_PAIRS >= 8 or die "Your terminal is too dumb for me\n";
 165         cbreak; noecho;
 166         $C->intrflush(0);
 167         $C->keypad(1);
 168         $C->meta(1);
 169         $C->clear;
 170         init_pair(1, COLOR_YELLOW, COLOR_BLUE);
 171         init_pair(2, COLOR_YELLOW, COLOR_RED);
 172         init_pair(3, COLOR_YELLOW, COLOR_BLACK);
 173         init_pair(4, COLOR_RED, COLOR_BLACK);
 174         init_pair(5, COLOR_BLUE, COLOR_BLACK);
 175
 176         $nrows = $C->getmaxy - 2;
 177         if ($BEX::Config::max_parallel_jobs > $nrows) {
 178                 $BEX::Config::max_parallel_jobs = $nrows;
 179         }
 180
 181         %host_state = %host_cnt = ();
 182         %job_state = %job_cnt = ();
 183         for my $s (@states) {
 184                 $host_cnt{$s} = 0;
 185                 $job_cnt{'*'}{$s} = 0;
 186         }
 187
 188         my $ui = bless {};
 189         $ui->refresh_status;
 190         return $ui;
 191 }
 192
 193 sub done($)
 194 {
 195         $C->bkgdset(COLOR_PAIR(1) | A_BOLD);
 196         $C->addstr($C->getmaxy-1, 0, "Press any key to quit...");
 197         $C->clrtoeol;
 198         $C->getch;
 199         endwin;
 200 }
 201
 202 sub err($$) {
 203         my ($ui, $msg) = @_;
 204         $C->bkgdset(COLOR_PAIR(2) | A_BOLD);
 205         $C->addnstr($C->getmaxy-1, 0, "ERROR: $msg", $C->getmaxx);
 206         $C->clrtoeol;
 207         $C->refresh;
 208 }
 209
 210 sub set_host_status($$$) {
 211         my ($ui, $mach, $stat) = @_;
 212         print STDERR "H: $mach $stat\n" if $debug;
 213         my $prev_stat = $host_state{$mach};
 214         if (defined $prev_stat) {
 215                 $host_cnt{$prev_stat}--;
 216         } else {
 217                 for my $s (@states) { $job_cnt{$mach}{$s} = 0; }
 218         }
 219         $host_state{$mach} = $stat;
 220         $host_cnt{$stat}++;
 221 }
 222
 223 sub set_job_status($$$$) {
 224         my ($ui, $mach, $jid, $stat) = @_;
 225         print STDERR "J: $mach $jid $stat\n" if $debug;
 226         my $prev_stat = $job_state{$mach}{$jid} // 'unknown';
 227         $job_cnt{$mach}{$prev_stat}--;
 228         $job_cnt{'*'}{$prev_stat}--;
 229         $job_state{$mach}{$jid} = $stat;
 230         $job_cnt{$mach}{$stat}++;
 231         $job_cnt{'*'}{$stat}++;
 232 }
 233
 234 sub refresh_status($) {
 235         $C->bkgdset(COLOR_PAIR(1) | A_BOLD);
 236         $C->addnstr(0, 0,
 237                 sprintf("BEX  Hosts: %dR %dD %dE %dW  Jobs: %dR %dD %dE %dW",
 238                         $host_cnt{'running'},
 239                         $host_cnt{'done'},
 240                         $host_cnt{'failed'},
 241                         $host_cnt{'ready'},
 242                         $job_cnt{'*'}{'running'},
 243                         $job_cnt{'*'}{'done'},
 244                         $job_cnt{'*'}{'failed'},
 245                         $job_cnt{'*'}{'ready'},
 246                 ), $C->getmaxx);
 247         $C->clrtoeol;
 248         $C->refresh;
 249 }
 250
 251 sub get_slot($) {
 252         my ($mach) = @_;
 253         my $s = $by_host{$mach};
 254         if (!defined $s) {
 255                 $s = $by_host{$mach} = { 'Host' => $mach };
 256         }
 257         return $s;
 258 }
 259
 260 my $place_counter;
 261
 262 sub place_slot($) {
 263         my ($s) = @_;
 264         $s->{'LastUpdate'} = $place_counter++;
 265         return $s if defined $s->{'Row'};
 266
 267         my $pri = $state_to_pri{$host_state{$s->{'Host'}}};
 268         my ($best, $besti);
 269         my $bestpri = -1;
 270         for my $i (0..$nrows-1) {
 271                 my $r = $by_row[$i];
 272                 if (!defined $r) {
 273                         $besti = $i;
 274                         $best = undef;
 275                         last;
 276                 }
 277                 my $rpri = $state_to_pri{$host_state{$r->{'Host'}}};
 278                 next if $rpri > $pri;
 279
 280                 if ($rpri < $bestpri ||
 281                     $rpri == $bestpri && $r->{'LastUpdate'} < $best->{'LastUpdate'}) {
 282                         # Trick: $best must be defined, as otherwise $bestpri == -1
 283                         $best = $r;
 284                         $besti = $i;
 285                         $bestpri = $rpri;
 286                 }
 287         }
 288
 289         if (defined $besti) {
 290                 if ($best) {
 291                         print STDERR "I: Replacing ", $best->{'Host'}, " (pri $bestpri)\n";
 292                         delete $best->{'Row'};
 293                 }
 294                 print STDERR "I: Allocated ", $s->{'Host'}, " \@$besti (pri $pri)\n";
 295                 $s->{'Row'} = $besti;
 296                 $by_row[$besti] = $s;
 297         } else {
 298                 print STDERR "I: No place for ", $s->{'Host'}, " (pri $pri)\n" if $debug;
 299         }
 300 }
 301
 302 sub redraw_slot($) {
 303         my ($s) = @_;
 304         my $r = $s->{'Row'} // return;
 305         $r++;
 306         my $mach = $s->{'Host'};
 307         my $stat = $s->{'Status'} // "?";
 308         my $jid = $s->{'Job'} // "";
 309         my $jname = ($jid eq "" ? "" : $queue->job_name($jid));
 310         my $jcnt = $job_cnt{$mach};
 311         if ($jcnt->{'running'}) {
 312                 if ($jcnt->{'failed'}) {
 313                         $C->bkgdset(COLOR_PAIR(4) | A_BOLD);
 314                 } else {
 315                         $C->bkgdset(COLOR_PAIR(3) | A_BOLD);
 316                 }
 317         } else {
 318                 if ($jcnt->{'failed'}) {
 319                         $C->bkgdset(COLOR_PAIR(4));
 320                 } else {
 321                         $C->bkgdset(0);
 322                 }
 323         }
 324         $C->addstr($r, 0, sprintf("%-20.20s", $mach));
 325         if ($jcnt->{'failed'}) {
 326                 $C->bkgdset(COLOR_PAIR(4));
 327                 $C->addstr(sprintf("%3dE ", $jcnt->{'failed'}));
 328         } else {
 329                 $C->bkgdset(0);
 330                 $C->addstr("     ");
 331         }
 332         $C->bkgdset(0);
 333         $C->addstr(sprintf("%3dD %3dW", $jcnt->{'done'}, $jcnt->{'ready'}));
 334         if ($stat eq 'DONE') {
 335                 if (defined $host_last_fail_stat{$mach}) {
 336                         $C->bkgdset(($host_last_fail_stat{$mach} eq 'NOPING') ? COLOR_PAIR(5) : COLOR_PAIR(4));
 337                         $C->addstr(sprintf("  %-8s %s", $host_last_fail_stat{$mach}, $queue->job_name($host_last_fail_job{$mach})));
 338                 }
 339         } else {
 340                 my $text = sprintf("  %-8s %s", $stat, $jname);
 341                 $C->addstr($text);
 342         }
 343         $C->clrtoeol;
 344         $C->refresh;
 345 }
 346
 347 sub update($$$$) {
 348         my ($ui, $mach, $jid, $stat) = @_;
 349         given ($stat) {
 350                 when ('READY') {
 351                         # Pseudo-state generated internally
 352                         $ui->set_host_status($mach, 'ready');
 353                         $ui->set_job_status($mach, $jid, 'ready');
 354                 }
 355                 when ('OK') {
 356                         $ui->set_job_status($mach, $jid, 'done');
 357                 }
 358                 when (['FAILED', 'INTERR', 'NOPING', 'PREPFAIL', 'NOXFER']) {
 359                         $ui->set_job_status($mach, $jid, 'failed');
 360                         $host_last_fail_job{$mach} = $jid;
 361                         $host_last_fail_stat{$mach} = $stat;
 362                 }
 363                 when ('DONE') {
 364                         if ($job_cnt{$mach}{'failed'}) {
 365                                 $ui->set_host_status($mach, 'failed');
 366                         } else {
 367                                 $ui->set_host_status($mach, 'done');
 368                         }
 369                 }
 370                 when ('INIT') {
 371                         $ui->set_host_status($mach, 'running');
 372                         $ui->set_job_status($mach, $jid, 'running') if defined $jid;
 373                 }
 374                 when ('LOCKED') {
 375                         if (defined $jid) {
 376                                 $ui->set_job_status($mach, $jid, 'failed');
 377                         } else {
 378                                 for my $j (keys %{$job_state{$mach}}) {
 379                                         $ui->set_job_status($mach, $jid, 'failed');
 380                                 }
 381                                 $ui->set_host_status($mach, 'failed');
 382                                 $host_last_fail_job{$mach} = $jid;
 383                                 $host_last_fail_stat{$mach} = $stat;
 384                         }
 385                 }
 386                 when (['START', 'PING', 'SEND', 'RUN']) {
 387                 }
 388                 default {
 389                         $ui->err("Received unknown job status $stat");
 390                 }
 391         }
 392         my $s = get_slot($mach);
 393         $s->{'Job'} = $jid;
 394         $s->{'Status'} = $stat;
 395         place_slot($s);
 396         redraw_slot($s);
 397         $ui->refresh_status;
 398 }