lib/bin/bex-add

   1 #!/usr/bin/perl
   2 # Batch EXecutor 3.0 -- Insert to Queue
   3 # (c) 2011-2012 Martin Mares <mj@ucw.cz>
   4
   5 use strict;
   6 use warnings;
   7 use Getopt::Long;
   8 use File::stat;
   9 use BEX;
  10
  11 my $given_body;
  12 my $given_go;
  13 my $given_id;
  14 my $queue_name;
  15 my $requeue_id;
  16 my $given_subject;
  17 my $given_template;
  18
  19 sub usage() {
  20         print <<AMEN ;
  21 Usage: bex add [<options>] [!]<machine-or-class> ...
  22
  23 Options:
  24 -b, --body=<file>       Load job body from the given file
  25 -g, --go                Do not run editor, go enqueue the job immediately
  26 -i, --id=<id>           Set job ID of the new job
  27 -q, --queue=<name>      Insert new jobs to the given queue
  28 -r, --requeue=<id>      Re-queue an existing job instead of creating a new one
  29 -s, --subject=<subj>    Set subject of the new job
  30 -t, --template=<file>   Load job template (headers and body) from the given file
  31 AMEN
  32         exit 0;
  33 }
  34
  35 GetOptions(
  36         "b|body=s" => \$given_body,
  37         "g|go!" => \$given_go,
  38         "i|id=s" => \$given_id,
  39         "q|queue=s" => \$queue_name,
  40         "r|requeue=s" => \$requeue_id,
  41         "s|subject=s" => \$given_subject,
  42         "t|template=s" => \$given_template,
  43         "help" => \&usage,
  44 ) or die "Try `bex add --help' for more information.\n";
  45
  46 # Prepare machine set
  47 @ARGV or die "No machines specified\n";
  48 my @machines = BEX::Config::parse_machine_list(@ARGV);
  49 @machines or die "No machines match\n";
  50
  51 my $queue = BEX::Queue->new($queue_name);
  52 my $job;
  53 my $tmp_fn;
  54
  55 if (defined $requeue_id) {
  56         # When requeueing, just fetch the existing job
  57         if (defined($given_body) || defined($given_id) || defined($given_subject) || defined($given_template)) {
  58                 die "Parameters of a requeued job cannot be changed\n";
  59         }
  60         my $fn = $queue->job_file($requeue_id);
  61         -f $fn or die "Job $requeue_id not known\n";
  62         $job = BEX::Job->new_from_file($fn);
  63 } else {
  64         # Create job template
  65         if (defined $given_template) {
  66                 $job = BEX::Job->new_from_file($given_template);
  67         } else {
  68                 $job = BEX::Job->new;
  69         }
  70         $job->attr('ID', $given_id) if defined $given_id;
  71         $job->attr('Subject', $given_subject) if defined $given_subject;
  72         if (defined $given_body) {
  73                 open B, '<', $given_body or die "Cannot open $given_body: $!\n";
  74                 local $/;
  75                 $job->attr('body', <B>);
  76                 close B;
  77         }
  78
  79         # Let the user edit the template
  80         if (!$given_go) {
  81                 $tmp_fn = $job->save;
  82                 my $orig_stat = stat($tmp_fn) or die;
  83                 system "editor", $tmp_fn and die "Editor exited with an error, file kept as $tmp_fn\n";
  84                 my $new_stat = stat($tmp_fn) or die "File $tmp_fn disappeared under my hands: $!\n";
  85                 if ($new_stat->mtime <= $orig_stat->mtime && $new_stat->size == $orig_stat->size) {
  86                         unlink $tmp_fn;
  87                         die "Cancelled\n";
  88                 }
  89                 $job = BEX::Job->new_from_file($tmp_fn);
  90         }
  91 }
  92
  93 # Put the job to the queue
  94 print "New job ", $job->id, "\n";
  95 $queue->save_job($job);
  96 for my $m (@machines) {
  97         if ($queue->enqueue($m, $job)) {
  98                 $queue->update_job_status($m, $job->id, 'NEW');
  99                 print "\t$m\n";
 100         } else {
 101                 $queue->log($m, $job->id, 'REQUEUE');
 102                 print "\t$m (already queued)\n";
 103         }
 104 }
 105
 106 # Remove the temporary file if there's any
 107 unlink $tmp_fn if defined $tmp_fn;