gal/bin/gal-gen

   1 #!/usr/bin/perl
   2 # UCW Gallery: Generate published photos
   3 # (c) 2004--2014 Martin Mares <mj@ucw.cz>
   4
   5 use strict;
   6 use warnings;
   7
   8 use UCW::Gallery;
   9 use Image::EXIF;
  10 use Image::Magick;
  11 use IO::Handle;
  12 use File::Spec;
  13 use File::Path;
  14
  15 STDOUT->autoflush(1);
  16
  17 my $gal = UCW::Gallery->load_config;
  18
  19 my $orig_list = $gal->read_list('gallery.list') or die "Cannot read gallery.list: $!\n";
  20
  21 my $photo_dir = $gal->get('PhotoDir');
  22 if (-d $photo_dir) {
  23         print "Using existing output directory: $photo_dir\n";
  24 } else {
  25         print "Creating output directory: $photo_dir\n";
  26         File::Path::mkpath($photo_dir) or die "Unable to create $photo_dir: $!\n";
  27 }
  28
  29 my $photo_meta = $gal->photo_meta_name;
  30 my $old_meta = {};
  31 if (-f $photo_meta) {
  32         print "Reading old meta-data\n";
  33         $old_meta = $gal->read_meta($photo_meta);
  34         # use Data::Dumper; print "Read old meta: ", Dumper($old_meta), "\n";
  35 }
  36 my $meta = { 'photo' => {} };
  37
  38 sub get_meta_basic($$$) {
  39         my ($f, $m, $p) = @_;
  40         my $rotate = $f->{orientation};
  41
  42         my ($orig_w, $orig_h, $orig_size, $orig_format) = $p->PingImage($f->{orig}) or die "Error reading " . $f->{orig} . "\n";
  43         print "${orig_w}x${orig_h} ";
  44
  45         my ($w0, $h0) = ($rotate eq "l" || $rotate eq "r") ? ($orig_h, $orig_w) : ($orig_w, $orig_h);
  46         my ($w, $h) = ($w0, $h0);
  47         if ($w > $gal->get('PhotoMaxWidth')) {
  48                 my $s = $gal->get('PhotoMaxWidth') / $w;
  49                 $w = $w * $s;
  50                 $h = $h * $s;
  51         }
  52         if ($h > $gal->get('PhotoMaxHeight')) {
  53                 my $s = $gal->get('PhotoMaxHeight') / $h;
  54                 $w = $w * $s;
  55                 $h = $h * $s;
  56         }
  57         $w = int($w + .5);
  58         $h = int($h + .5);
  59
  60         $m->{o} = $rotate;
  61         $m->{xf} = $f->{xfrm};
  62         $m->{w0} = $w0;
  63         $m->{h0} = $h0;
  64         $m->{w} = $w;
  65         $m->{h} = $h;
  66 }
  67
  68 sub parse_geo($) {
  69         my ($g) = @_;
  70         defined $g or return;
  71         if ($g =~ m{^([NEWS]) (\d+)\xb0 ([0-9.]+)'$}) {
  72                 $g = $2 + $3/60;
  73                 $g = -$g if $1 eq 'W' || $1 eq 'S';
  74         } elsif ($g =~ m{^([NEWS]) (\d+)\xb0 (\d+)' ([0-9.]+)$}) {
  75                 $g = $2 + $3/60 + $4/3600;
  76                 $g = -$g if $1 eq 'W' || $1 eq 'S';
  77         } else {
  78                 print "[EXIF: unable to parse coordinate $g] ";
  79                 return;
  80         }
  81         return sprintf "%.6f", $g;
  82 }
  83
  84 sub get_meta_exif($$) {
  85         my ($f, $m) = @_;
  86         $gal->get('CacheExif') or return;
  87
  88         my $e = new Image::EXIF($f->{orig});
  89         my $i = $e->get_all_info();
  90         if ($e->error) {
  91                 print "[EXIF error: ", $e->error, "] ";
  92                 return;
  93         }
  94         # use Data::Dumper; print Dumper($i);
  95
  96         my $lat = parse_geo($i->{image}->{'Latitude'});
  97         my $lon = parse_geo($i->{image}->{'Longitude'});
  98
  99         my $alt = $i->{image}->{'Altitude'};
 100         if ($alt) {
 101                 if ($alt =~ m{^([0-9.]+) m$}) {
 102                         $alt = $1;
 103                 } else {
 104                         print "[EXIF: unable to parse altitude $alt] ";
 105                         $alt = undef;
 106                 }
 107         }
 108
 109         # printf "[GEO: lat=%s lon=%s alt=%s] ", $lat // '?', $lon // '?', $alt // '?';
 110         if ($lat && $lon) {
 111                 $m->{lat} = $lat;
 112                 $m->{lon} = $lon;
 113         }
 114         $m->{alt} = $alt if $alt;
 115
 116         my $time = $i->{image}->{'Image Created'};
 117         if ($time) {
 118                 if ($time =~ m{^(\d{4}):(\d{2}):(\d{2}) (\d{2}:\d{2}:\d{2})$}) {
 119                         $m->{t} = "$1-$2-$3 $4";
 120                         # print "[TIME: ", $m->{t}, "] ";
 121                 } else {
 122                         print "[EXIF: unable to parse time $time] ";
 123                 }
 124         }
 125 }
 126
 127 sub generate_photo($$$) {
 128         my ($f, $m, $p) = @_;
 129
 130         my $e;
 131         $e = $p->Read($f->{orig}) and die "Error reading " . $f->{orig} . ": $e";
 132         $p->Strip;
 133         $p->SetAttribute(quality=>90);
 134
 135         my $xfrm = $m->{xf};
 136         if ($xfrm =~ /s/) {
 137                 print "-> sharpen ";
 138                 $p->Sharpen(1);
 139         }
 140         if ($xfrm =~ /h/) {
 141                 print "-> equalize ";
 142                 $p->Equalize();
 143         }
 144         if ($xfrm =~ /n/) {
 145                 print "-> normalize ";
 146                 $p->Normalize();
 147         }
 148
 149         my $rotate = $m->{o};
 150         my $rot = 0;
 151         if ($rotate eq "l") { $rot = 270; }
 152         elsif ($rotate eq "r") { $rot = 90; }
 153         elsif ($rotate eq "u") { $rot = 180; }
 154         if ($rot) {
 155                 print "-> rotate $rot ";
 156                 $p->Rotate(degrees=>$rot);
 157         }
 158
 159         my ($w, $h) = ($m->{w}, $m->{h});
 160         if ($w != $m->{w0} || $h != $m->{h0}) {
 161                 print "-> ${w}x${h} ";
 162                 $p->Resize(width=>$w, height=>$h);
 163         }
 164
 165         my $photo = $gal->photo_name($m, $f->{id});
 166         my $tmp = "$photo.new";
 167         $e = $p->Write($tmp) and die "Unable to write $tmp: $e";
 168         rename $tmp, $photo or die "Cannot rename $tmp to $photo: $!\n";
 169 }
 170
 171 for my $f (@$orig_list) {
 172         my $id = $f->{id};
 173         print "$id: ";
 174
 175         my $m = { };
 176         $meta->{photo}->{$id} = $m;
 177         $f->{orig} = File::Spec->rel2abs($f->{file}, $gal->get('OrigDir'));
 178
 179         my $p = new Image::Magick;
 180         get_meta_basic($f, $m, $p);
 181         get_meta_exif($f, $m);
 182
 183         my $om = $old_meta->{photo}->{$id};
 184         if ($om &&
 185             $om->{o} eq $m->{o} &&
 186             $om->{xf} eq $m->{xf} &&
 187             $om->{w} eq $m->{w} &&
 188             $om->{h} eq $m->{h}) {
 189                 print "... uptodate\n";
 190                 next;
 191         }
 192
 193         generate_photo($f, $m, $p);
 194         print "... OK\n";
 195 }
 196
 197 print "Cleaning up stale files\n";
 198 for my $f (<$photo_dir/*.jpg>) {
 199         my ($vv, $dd, $id) = File::Spec->splitpath($f);
 200         $id =~ s{\..*$}{};
 201         unless (defined $meta->{photo}->{$id}) {
 202                 print "$id: removing\n";
 203                 unlink $f;
 204         }
 205 }
 206
 207 print "Writing meta-data\n";
 208 $gal->write_meta($photo_meta, $meta);
 209 exit 0;