bq

   1 #!/usr/bin/perl
   2 # Batch EXecutor 2.0 -- Show Queued Jobs
   3 # (c) 2011 Martin Mares <mj@ucw.cz>
   4
   5 use strict;
   6 use warnings;
   7 use Getopt::Long;
   8 use POSIX;
   9
  10 use lib 'lib';
  11 use BEX;
  12
  13 my $by_host;
  14 my $queue_name;
  15
  16 GetOptions(
  17         "h|by-host!" => \$by_host,
  18         "q|queue=s" => \$queue_name,
  19 ) or die <<AMEN ;
  20 Usage: bq [<options>] [[!]<machine-or-class> ...]
  21
  22 Options:
  23 -h, --by-host           Show jobs sorted by host (default: by job)
  24 -q, --queue=<name>      Show jobs in the given queue
  25 AMEN
  26
  27 my @machines = BEX::Config::parse_machine_list(@ARGV ? @ARGV : '*');
  28 my $queue = BEX::Queue->new($queue_name);
  29
  30 if ($queue->is_locked(undef, undef)) {
  31         print "### Queue lock present\n\n";
  32 }
  33
  34 my %jobs = ();
  35 my %machs = ();
  36 my %subj = ();
  37 my %stat = ();
  38 my %mach_locked = ();
  39 for my $m (@machines) {
  40         $mach_locked{$m} = $queue->is_locked($m, undef);
  41         for my $j ($queue->scan($m)) {
  42                 push @{$jobs{$j}}, $m;
  43                 push @{$machs{$m}}, $j;
  44                 my $job = $queue->job_metadata($j);
  45                 $subj{$j} = ' (' . $job->{'Subject'} . ')';
  46                 my $st = $queue->read_job_status($m, $j);
  47                 if (defined($st->{'Time'}) && defined($st->{'Status'})) {
  48                         $stat{$m}{$j} = ' [' . $st->{'Status'} . ' on ' .
  49                                         POSIX::strftime('%Y-%m-%d', localtime $st->{'Time'}) . ']';
  50                 } else {
  51                         $stat{$m}{$j} = '';
  52                 }
  53                 if ($mach_locked{$m} || $queue->is_locked($m, $j)) {
  54                         $stat{$m}{$j} .= ' [LOCKED]';
  55                 }
  56         }
  57 }
  58
  59 if ($by_host) {
  60         for my $m (sort keys %machs) {
  61                 print "$m", ($mach_locked{$m} ? ' [LOCKED]' : ''), "\n";
  62                 for my $j (@{$machs{$m}}) {
  63                         print "\t$j", $subj{$j}, $stat{$m}{$j}, "\n";
  64                 }
  65         }
  66 } else {
  67         for my $j (sort keys %jobs) {
  68                 print $j, $subj{$j}, "\n";
  69                 for my $m (sort @{$jobs{$j}}) {
  70                         print "\t$m", $stat{$m}{$j}, "\n";
  71                 }
  72         }
  73 }