bin/gal-mj-digikam

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd;
   7 use DBI;
   8 use Getopt::Long;
   9
  10 if (@ARGV && $ARGV[0] eq '--help') {
  11         die <<AMEN ;
  12 Usage: gal mj-digikam [<album>]
  13 AMEN
  14 }
  15
  16 my $photos_root = $ENV{HOME} . '/photos';
  17
  18 my $album = $ARGV[0];
  19 if (!defined $album) {
  20         my $cwd = getcwd;
  21         $cwd =~ m{/photos/(.*)} or die "Cannot identify album from current directory, need to specify maunally.\n";
  22         $album = $1;
  23 }
  24
  25 if (! -f "gallery.cf") {
  26         system 'gal', 'mj-init'; die if $?;
  27 }
  28
  29 my $dbfile = "$photos_root/digikam4.db";
  30 my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile", "", "") or die "Cannot access $dbfile\n";
  31
  32 my %alba = ();
  33 for my $r (@{$dbh->selectall_arrayref(
  34         'SELECT a.id AS id, r.label AS label, a.relativePath AS rpath FROM Albums a JOIN AlbumRoots r ON (r.id = a.albumRoot)',
  35         { Slice => {} })}) {
  36         my $name = $r->{label} . $r->{rpath};
  37         # print "$name\n";
  38         $alba{$name} = $r->{id};
  39 }
  40
  41 my $album_id = $alba{$album} // die "Unknown album $album\n";
  42 print "## Album $album: id=$album_id\n";
  43
  44 my ($tag_id) = $dbh->selectrow_array('SELECT id FROM Tags WHERE pid=0 AND name="web"');
  45 $tag_id // die "Cannot find web tag\n";
  46 print "## Tag ID: $tag_id\n";
  47
  48 my $res = $dbh->selectall_arrayref( <<AMEN, { Slice => {} },
  49         SELECT
  50                 i.name AS name,
  51                 p.latitudeNumber AS lat,
  52                 p.longitudeNumber AS lon,
  53                 p.altitude AS alt
  54         FROM Images i
  55         JOIN ImageTags t ON (i.id = t.imageid)
  56         LEFT JOIN ImagePositions p ON (i.id = p.imageid)
  57         WHERE i.album=? AND t.tagid=?
  58         ORDER BY i.modificationDate
  59 AMEN
  60         $album_id,
  61         $tag_id,
  62         );
  63
  64 open OUT, '|-', $ENV{GALLERY_ROOT} . '/bin/gal-scan' or die "Cannot feed gal scan\n";
  65 for my $r (@$res) {
  66         print OUT "$photos_root/$album/" . $r->{name}, "\n";
  67         for my $k (qw(lat lon alt)) {
  68                 print OUT "\t$k=", $r->{$k}, "\n" if defined $r->{$k};
  69         }
  70 }
  71 close OUT;