bin/gal-mj-digikam

   1 #!/usr/bin/perl
   2 # This is a hack, which takes a Digikam album, finds all photos
   3 # possessing a "web" tag and imports them to UCW::Gallery.
   4
   5 use common::sense;
   6
   7 use Cwd;
   8 use DBI;
   9 use Getopt::Long;
  10
  11 if (@ARGV && $ARGV[0] eq '--help') {
  12         die <<AMEN ;
  13 Usage: gal mj-digikam [<album>]
  14 AMEN
  15 }
  16
  17 my $photos_root = $ENV{HOME} . '/photos';
  18
  19 my $album = $ARGV[0];
  20 if (!defined $album) {
  21         my $cwd = getcwd;
  22         $cwd =~ m{/photos/(.*)} or die "Cannot identify album from current directory, need to specify maunally.\n";
  23         $album = $1;
  24 }
  25
  26 if (! -f "gallery.cf") {
  27         system 'gal', 'mj-init'; die if $?;
  28 }
  29
  30 my $dbfile = "$photos_root/digikam4.db";
  31 my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile", "", "") or die "Cannot access $dbfile\n";
  32
  33 my %alba = ();
  34 for my $r (@{$dbh->selectall_arrayref(
  35         'SELECT a.id AS id, r.label AS label, a.relativePath AS rpath FROM Albums a JOIN AlbumRoots r ON (r.id = a.albumRoot)',
  36         { Slice => {} })}) {
  37         my $name = $r->{label} . $r->{rpath};
  38         # print "$name\n";
  39         $alba{$name} = $r->{id};
  40 }
  41
  42 my $album_id = $alba{$album} // die "Unknown album $album\n";
  43 print "## Album $album: id=$album_id\n";
  44
  45 my ($tag_id) = $dbh->selectrow_array('SELECT id FROM Tags WHERE pid=0 AND name="web"');
  46 $tag_id // die "Cannot find web tag\n";
  47 print "## Tag ID: $tag_id\n";
  48
  49 my $res = $dbh->selectall_arrayref( <<AMEN, { Slice => {} },
  50         SELECT
  51                 i.name AS name,
  52                 p.latitudeNumber AS lat,
  53                 p.longitudeNumber AS lon,
  54                 p.altitude AS alt
  55         FROM Images i
  56         JOIN ImageTags t ON (i.id = t.imageid)
  57         LEFT JOIN ImagePositions p ON (i.id = p.imageid)
  58         WHERE i.album=? AND t.tagid=?
  59         ORDER BY i.modificationDate
  60 AMEN
  61         $album_id,
  62         $tag_id,
  63         );
  64
  65 open OUT, '|-', $ENV{GALLERY_ROOT} . '/bin/gal-scan' or die "Cannot feed gal scan\n";
  66 for my $r (@$res) {
  67         print OUT "$photos_root/$album/" . $r->{name}, "\n";
  68         for my $k (qw(lat lon alt)) {
  69                 print OUT "\t$k=", $r->{$k}, "\n" if defined $r->{$k};
  70         }
  71 }
  72 close OUT;